*DECK +CHECK
CHECK,T37.
*CALL USER
*CALL CHARGE
*CALL BANNER
* 
* DOES- 
*   CREATES PERMANENT FILE *CHECK*. 
* 
RFL(70000)
COMPASS(S=SYSTEXT,S=CPUTEXT)
REWIND(LGO) 
PURGE(CHECK/NA) 
RETURN(CHECK) 
DEFINE(CHECK) 
MAP,FULL. 
LOAD,LGO. 
NOGO(CHECK) 
ATTACH(CHECK) 
COPYBF(INPUT,COMPILE) 
REWIND(COMPILE) 
CHECK(COMPILE)
IFE,SW2=T,SW3CK1. 
DISPLAY,1.
ELSE,SW3CK1.
DISPLAY,0.
COPYBR(COMPILE,OUTPUT)
ENDIF,SW3CK1. 
CHECK(COMPILE)
IFE,SW2=T,SW3CK2. 
DISPLAY,1.
ELSE,SW3CK2.
DISPLAY,0.
ENDIF,SW3CK2. 
COPYBR(COMPILE,OUTPUT)
CATLIST.
EXIT. 
DMP.
DMP,0,70000.
*WEOR,0 
          IDENT  CHECK
          ENTRY  CHECK
          TITLE  CHECK -  CHECK FOR NULL FILE 
**        CHECK - CHECK FOR NULL FILE 
* 
*     CALLING SEQUENCE- 
*         CHECK(<FILE-NAME>)
* 
*     DOES- 
*         IF THE NEXT RECORD ON <FILE-NAME> IS EMPTY, 
*             SETS SW2 = 1 (TRUE) AND 
*             SKIPS THE EMPTY RECORD. 
*         ELSE (IF THE RECORD HAS SOMETHING), 
*             SETS SW2 = 0 (FALSE), AND 
*             LEAVES <FILE-NAME> POSITIONED AT THE BEGINNING OF THE 
*                 RECORD. 
  
  
 CHECK    SB1    1
          B1=1               TELL MACROS THAT B1 IS 1 
  
*     SET UP FILE NAME
  
          SA1    2           42/0L_<FILE-NAME>, 18/JUNK 
          MX0    42          77777777777777000000B
          BX1    X0*X1       42/0L_<FILE-NAME>, 18/0
          SA2    COMPILE     42/0L_COMPILE, 18/CODE+STATUS
          BX2    -X0*X2      42/0, 18/CODE+STATUS 
          BX6    X1+X2       42/0._<FILE-NAME>, 18/CODE+STATUS
          SA6    COMPILE
  
*     SET BUFFER POINTERS 
  
          SX6    BUFF 
          SA6    COMPILE+2       IN = FIRST = OUT 
          SA6    COMPILE+3
          READ   COMPILE,R       READ A PRU 
          SA1    COMPILE
          LX1    59-4 
          PL     X1,NOTNULL  JP IF NOT EOR - NOT NULL 
          SA2    COMPILE+2       GET IN 
          SX2    X2-BUFF
          NZ     X2,NOTNULL  JP IF NOT EMPTY
          ONSW   2           TURN ON SWITCH 2 
          EQ     SETRTN 
 NOTNULL  BSS    0
          BKSPRU COMPILE,1,R     BACKSPACE PRU READ 
          OFFSW  2           TURN OFF SWITCH 2
 SETRTN   BSS    0
          ENDRUN RETURN      STOP 
 COMPILE  FILEB  BUFF,65
 BUFF     BSS    65 
 JCIWD    BSSZ   5
          END    CHECK
*WEOR,0 
 FIRST RECORD - NOT NULL. 
 SECOND IS NULL.
*WEOR,0 
*WEOR,0 
 THIRD RECORD - SHOULD FOLLOW WORDS "SECOND IS NULL". 
*WEOR,17
