*DECK     WLB 
          IDENT  WLB
          TITLE  WLB - WAIT FOR ACK OF LAST BLOCK.
          SST 
          SYSCOM B1 
  
  
          ENTRY  WLB
  
          COMMENT  WAIT FOR ACK OF LAST BLOCK.
          COMMENT COPYRIGHT CONTROL DATA SYSTEMS INC. 1994. 
          SPACE  4,10 
**        WLB - WAIT FOR ACK OF LAST BLOCK. 
* 
*         J. G. CLARK        80/03/25.
          SPACE  4,10 
**        COMMON DECKS. 
  
  
*CALL COMCMAC 
*CALL COMCAPR 
*CALL COMCPTF 
 WLB      SPACE  4,10 
**               WLB WILL WAIT FOR THE BACK CORRESPONDING TO
*         THE LAST BLOCK SENT.  THIS IS ACCOMPLISHED BY CHECKING
*         BACK MESSAGES FOR AN ABN MATCHING THE LAST SENT BLOCK.
*         WLB WILL RETURN ONLY AFTER RECEIVING THE LAST BACK OR 
*         IF AN ERROR OCCURES.
* 
*         ENTRY  (A1) IS THE ADDRESS OF THE PARAMETER LIST. 
* 
*         PARAMETER LIST FORMAT 
*         NSUP   - SUPERVISORY/INPUT QUEUED AS DEFINED BY NETON.
*         STAT   - CONNECTION STATUS INDICATOR. 
*                - SET TO -0 IF THE CONNECTION IS BROKEN. 
*         ACKT   - NETWAIT TIME INTERVAL. 
*         WAITF  - NETWAIT FLAG AS DEFINED BY NETWAIT.
*         HA     - HEADER AREA FOR DATA BLOCK RETURNED. 
*         TA     - TEXT AREA TO BE RETURNED BY NETGET.
*         MAXTLC - MAXIMUM TEXT AREA AVAILABLE FOR NETGET.
* 
*         EXIT   (X1) IS AN ERROR MESSAGE ADDRESS (ZERO IF NONE). 
*                (X6) IS NON-ZERO IF INPUT WAS AVAILABLE. 
* 
*         USES   A - 1,2,3. 
*                B - NONE.
*                X - 1,2,3,6. 
* 
*         CALLS  GMB, WMBS. 
  
  
 WLB      SUBRL  (,#STAT) 
          SX1    B0+
          SX6    B0+
 WLB1     SA2    ABN         CHECK LAST SENT ABN WITH RECEIVED
          SA3    A2+B1
          BX3    X2-X3
          ZR     X3,WLBX     IF LAST BACK WAS RECEIVED
          SA1    A0 
          RJ     =XWMBS      WAIT FOR SUPERVISORY MESSAGE 
          NZ     X1,WLBX     IF ERROR DETECTED
          SA1    "STAT" 
          RJ     =XGMB       GET SUPERVISORY MESSAGE
          NZ     X1,WLBX     IF ERROR IN BLOCK RECEIVE
          MI     X6,WLBX     IF NAK RECEIVED
          EQ     WLB1        IF NO ERROR OCCURRED 
  
          QUAL   *
          SPACE  4
          END 
