*DECK,UPKHELP 
USETEXT COMCBEG 
USETEXT COMQDEF 
USETEXT COMQKDS 
USETEXT COMQKRS 
USETEXT COMQSEL 
    PROC UPKHELP; 
      BEGIN  # UPKHELP #
# 
**    UPKHELP     UPDATE HELP DISPLAY.
* 
*     UPDATES THE HELP K DISPLAY. 
* 
*     PROC UPKHELP
* 
*     ENTRY      DISPLAY HEADER INITIALIZED FOR HELP DISPLAY. 
* 
*     EXIT       DISPLAY ITEM AREA UPDATED. 
* 
*     PROCESS    MOVE HELP DISPLAY TO ITEM AREA.
* 
# 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        PROC MOVEI;                # MOVE WORDS # 
        PROC NAME;                 # DEBUG CODE # 
        FUNC XCDD       C(10);     # CONVERT DECIMAL TO DPC # 
        END 
  
# 
****  XREF END
# 
  
    CONTROL IFEQ OS$NOSBE;
      ITEM I          I;           # LOOP VARIABLE #
      ITEM TEMPC      C(10);       # TEMPORARY CHARACTER VARIABLE # 
    CONTROL ENDIF;
  
        $BEGIN
        NAME("UPKHELP");           # DEBUG CODE # 
        $END
  
    CONTROL IFEQ OS$NOSBE;
      KR$FSRL[MNFSI] = "     0";
      FOR I = (MNFSI + 1) STEP 1 UNTIL MXFSI
      DO
        BEGIN 
        TEMPC = XCDD(FSIU[I-1] * FSIUNIT);
        KR$FSRU[I-1] = C<4,6>TEMPC; 
        TEMPC = XCDD( ( (FSIL[I] - 1) * FSIUNIT) + 1);
        KR$FSRL[I] = C<4,6>TEMPC; 
        END 
  
      KR$FSRU[MXFSI] = "999999";
    CONTROL ENDIF;
  
      MOVEI( (MXITEMS*KDWDSPERLN), LOC(KR$IT), LOC(KL$IT) );
  
      END  # UPKHELP #
    TERM
