*DECK,UPDKDSP 
USETEXT COMCBEG 
USETEXT COMQDEF 
USETEXT COMQKDS 
    PROC UPDKDSP; 
      BEGIN  # UPDKDSP #
# 
**    UPDKDSP    UPDATE K DISPLAY.
* 
*     UPDATES THE K DISPLAY.
* 
*     PROC UPDKDSP
* 
*     ENTRY      KDISORD = CURRENT K DISPLAY ORDINAL
*                KDISPREV = PREVIOUS K DISPLAY ORDINAL
*                KS$UPDATE[N] = TRUE, IF CORRESPONDING DISPLAY REQUIRES 
*                                     UPDATING. 
* 
*     EXIT       DISPLAY UPDATED. 
* 
*     PROCESS    IF CURRENT DISPLAY NOT EQUAL TO PREVIOUS DISPLAY:  
*                  CALL UPKHDR TO UPDATE DISPLAY HEADER INFORMATION.
*                CALL ROUTINE TO GENERATE DISPLAY.
* 
# 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        PROC NAME;                 # DEBUG CODE # 
        PROC UPKHDR;               # UPDATE K DISPLAY HEADER #
        PROC UPKHELP;              # UPDATE HELP DISPLAY #
        PROC UPKPID;               # UPDATE STATUS,PID DISPLAY #
        PROC UPKSC;                # UPDATE STATUS,SC DISPLAY # 
        PROC UPKTR;                # UPDATE STATUS,TRANSFER DISPLAY # 
        END 
  
# 
****  XREF END
# 
  
      SWITCH SW$KDIS:KDIS 
         SW$HELP   :HELP           # HELP # 
        ,SW$PID    :PID            # STATUS,PID # 
        ,SW$SC     :SC             # STATUS,SC #
        ,SW$TRANSFE:TRANSFE        # STATUS,TRANSFER #
        ; 
  
        $BEGIN
        NAME("UPDKDSP");           # DEBUG CODE # 
        $END
  
      IF KDISPREV NE KDISORD
      THEN
        BEGIN 
        KDISPREV = KDISORD; 
        UPKHDR; 
        END 
  
      GOTO SW$KDIS[KDISORD];       # CASE STATEMENT # 
  
SW$HELP:                           # HELP # 
        UPKHELP;
        GOTO SW$END;
  
SW$PID:                            # STATUS,PID # 
        UPKPID; 
        GOTO SW$END;
  
SW$SC:                             # STATUS,SC #
        UPKSC;
        GOTO SW$END;
  
SW$TRANSFE:                        # STATUS,TRANSFER #
        UPKTR;
        GOTO SW$END;
  
SW$END:                            # END OF CASE #
  
      KS$UPDATE[KDISORD] = FALSE; 
  
      END  # UPDKDSP #
    TERM
