*DECK     TNL 
          IDENT  TNL
          TITLE  TNL - TERMINATE NETWORK LINK.
          SST 
          SYSCOM B1 
  
  
          ENTRY  TNL
  
          COMMENT  TERMINATE NETWORK LINK.
          COMMENT COPYRIGHT CONTROL DATA SYSTEMS INC. 1994. 
          SPACE  4,10 
**        TNL - TERMINATE NETWORK LINK. 
* 
*         J. G. CLARK        79/12/17.
          SPACE  4,10 
**        COMMON DECKS. 
  
  
*CALL COMCMAC 
*CALL CMACROS 
 TNL      SPACE  4,10 
**               TNL TERMINATES THE CONNECTION WITH THE NETWORK 
*         BY *CON/END/*ING THE APPLICATION CONNECTION AND 
*         CALLING NETOFF.  THE CONNECTION STATUS INDICATOR
*         IS SET TO THE NEXT STATUS BEFORE ATTEMPTING THE 
*         NEXT FUNCTION.  IN THIS WAY TERMINATION IS GUARENTEED 
*         EVEN IF ALL THE STEPS FAIL. 
* 
*         ENTRY  (A1) IS THE ADDRESS OF THE PARAMETER LIST. 
* 
*         PARAMETER LIST FORMAT 
*         NSUP   - SUPERVISORY/INPUT QUEUED, AS DEFINED BY NETON. 
*         STAT   - COMMUNICATIONS STATUS INDICATOR. 
*                - SET TO -0 IF A CONNECTION BROKEN IS RECEIVED.
*         ACKT   - NETWAIT TIME INTERVAL. 
*         FLAG   - NETWAIT DEFINED WAIT FLAG. 
*         HA     - HEADER AREA FOR NETGET.
*         TA     - TEXT AREA TO BE RETURNED FROM NETGET.
* 
*         EXIT   STAT IS SET TO 5 (NO CONNECTION).
* 
*         USES   A - 1,2,3,6. 
*                B - NONE.
*                X - 1,2,3,6. 
* 
*         CALLS  RML, STT, NETOFF, NETPUT.
          NSTORE X1,ABHADR=B0 
          NSTORE X1,ABHABT=3
  
  
 TNL      SUBRL  (,#STAT,,,#NPUT,#MB) 
          SA1    "STAT" 
          SB1    1
          SA2    X1+
          MI     X2,TNL1     IF CONNECTION STILL GOOD 
          ZR     X2,TNL2     IF STILL NETTED ON 
          EQ     TNLX        IF NOT NETTED ON 
  
 TNL1     BX6    X6-X6
          SA6    A2          SET STATUS TO NOT CONNECTED
          SA3    "MB" 
          NSTORE X3,PFCSFC=CONEND 
          NSTORE X3,CONACN=B1 
          SA1    "NPUT" 
          NSTORE X1,ABHTLC=2
          NSTORE X1,ABHACT=B1 
          NSTORE X1,ABHABT=3
          NSTORE X1,ABHADR=B0 
          RJ     =XFTUPUT    PUT THE CON/END/R
          RJ     =XSTT       SET TIMEOUT TIME 
          SA1    A0 
          RJ     =XRML       RECEIVE MESSAGE FROM LINK
 TNL2     SA1    "STAT" 
          SX6    5
          SA6    X1          SET NOT NETTED ON STATUS 
          RJ     =XFTUOFF 
          SB1    1
          EQ     TNLX        RETURN 
  
  
          QUAL   *
          SPACE  4
          END 
