*DECK     SML 
          IDENT  SML
          TITLE  SML - SEND MESSAGE TO LINK.
          SST 
          SYSCOM B1 
  
  
          ENTRY  SML
  
          COMMENT  SEND MESSAGE TO LINK.
          COMMENT COPYRIGHT CONTROL DATA SYSTEMS INC. 1994. 
          SPACE  4,10 
**        SML - SEND MESSAGE TO LINK. 
* 
*         J. G. CLARK        79/12/17.
          SPACE  4,10 
**        COMMON DECKS. 
  
  
*CALL COMCMAC 
*CALL COMCAPR 
*CALL COMCPTF 
 SML      SPACE  4,10 
**               SML IS CALLED TO SEND A MESAGE BLOCK TO THE LINKED 
*         MAINFRAME WHEN NO RESPONSE IS EXPECTED.  THE MESSAGE
*         BLOCK IS NETPUT ACCROSS THE NETWORK AND THE 
*         ACKNOWLEDGE IS WAITED FOR.  IF AN INPUT MESSAGE 
*         OCCURES BEFORE THE *BACK*, IT IS IGNORED.  NEGATIVE 
*         ACKNOWLEDGES ARE RETRIED. 
* 
*         ENTRY  SMB CONTAINS THE MESSAGE BLOCK TO SEND.
* 
*         EXIT   (X1) IS AN ERROR MESSAGE ADDRESS IF A NETWORK
*                OR PROTOCOL ERROR OCCURS.
*                THE *BACK* HAS BEEN RECEIVED.
* 
*         USES   A - 1,2,3. 
*                B - NONE.
*                X - 1,2,3,6. 
* 
*         CALLS  PMB, WLB.
  
  
 SML      SUBRL  (,,#QBIT,#STAT)
          SX6    -NAKRTRY-1  SET MAXIMUM NUMBER OF NAK RETRIES
          SA6    SMLA 
 SML1     SA1    A0 
          RJ     =XPMB       PUT MESSAGE BLOCK
          SA1    "QBIT" 
          RJ     =XWLB       WAIT FOR LAST BACK 
          NZ     X1,SMLX     IF ERROR IN BLOCK RECEIVE
          PL     X6,SMLX     IF A NAK NOT RECEIVED
          SA2    SMLA 
          SX1    BNAM        SET DAYFILE MESSAGE
          SX6    X2+B1
          PL     X6,SMLX     IF NUMBER OF RETRIES EXAUSTED
          SA6    A2 
          EQ     SML1        RESEND THE LAST MESSAGE
  
 SMLA     BSS    1
  
  
          QUAL   *
          SPACE  4
          END 
