*DECK PUTNTA
USETEXT COMCBEG 
USETEXT COMCAPR 
USETEXT COMCCAE 
USETEXT COMQDEF 
USETEXT COMQFIL 
USETEXT COMQNET 
      PROC PUTNTA;
        BEGIN    # PUTNTA # 
# 
**    PUTNTA     SEND LEVEL 7 NETWORK MESSAGE.
* 
*     PUTNTA BUILDS THE NETWORK HEADER FOR THE LEVEL 7 MESSAGE THAT 
*     IS IN THE BUFFER AT THE HEAD OF THE NETPUT CHAIN AND CALLS
*     NETPUT TO TRANSMIT THE BLOCK.  THE BLOCK WILL BE RELEASED 
*     BY *FCACKM* WHEN ACKNOWLEDGED BY THE SUBSYSTEM. 
* 
*     PROC PUTNTA 
* 
*     ENTRY      ACN = APPLICATION CONNECTION NUMBER. 
*                FILENHA = HEAD OF NETPUT BUFFER CHAIN. 
* 
*     EXIT       AFT ENTRY STATUS UPDATED.
*                FILEABN (APPLICATION BLOCK NUMBER) INCREMENTED.
*                FILETIM = CURRENT TIME.
* 
*     PROCESS    IF BUFFER IN CHAIN:  
                   IF NOT RETRY:  
*                    UPDATE AFT ENTRY 
*                    BUILD MESSAGE HEADER.
*                  CALL NETPUT (SEND MESSAGE).
# 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        PROC FTUPUT;               # NETPUT INTERFACE # 
        PROC NAME;                 # DEBUG CODE # 
        PROC NSTORE;
        END 
# 
****  XREF END
# 
  
      BASED 
      ARRAY HDR$HDR  [0:0] S(1);
        BEGIN 
        ITEM $DUMMY     U(00,00,60);
        END 
  
  
      $BEGIN
      NAME ("PUTNTA");             # DEBUG CODE # 
      $END
  
      IF (FILENHA NE 0) 
      THEN
        BEGIN 
        P<NHA$B> = FILENHA;        # SET BLOCK ADDRESS #
        P<NTA$B> = LOC(NTA$); 
        P<HDR$HDR> = LOC(NHA$); 
        IF FILENAK EQ 0            # IF NOT RETRY # 
        THEN
          BEGIN 
          FILEABN = FILEABN + 1;
          NHA$ = MSGHDR;           # MESSAGE HEADER # 
          NSTORE(HDR$HDR,$ABHABN,FILEABN);  # BLOCK NUMBER #
          NSTORE(HDR$HDR,$ABHTLC,NTA$HCC);  # CHAR COUNT #
          NSTORE(HDR$HDR,$ABHADR,ACN);  # CONNECTION NO. #
          FILETIM = TIMT;          # SAVE FOR TIMING OUT CONNECTION # 
          FILEFTS = FTS$WNMSG;
          END 
  
        FTUPUT(HDR$HDR,NTA$B);   # SEND MESSAGE # 
        END 
  
      END      # PUTNTA # 
    TERM
