*DECK     PRP 
          IDENT  PRP
          TITLE  PRP - PROCESS REMAINING PARAMETERS.
          SST 
          SYSCOM B1 
  
  
          ENTRY  PRP
  
          COMMENT  PROCESS REMAINING PARAMETERS.
          COMMENT COPYRIGHT CONTROL DATA SYSTEMS INC. 1994. 
          SPACE  4,10 
**        PRP - PROCESS REMAINING PARAMETERS. 
* 
*         J. G. CLARK        80/01/16.
          SPACE  4,10 
**        COMMON DECKS. 
  
  
*CALL COMCMAC 
*CALL COMCAPR 
*CALL COMCPTF 
 PRP      SPACE  4,10 
**               PRP IS CALLED TO PROCESS ANY LEVEL 7 PROTOCOL
*         PARAMETERS REMAINING IN THE MESSAGE BLOCK.  THE ADDRESS 
*         OF THE PROCESSOR TABLE SUPPLIED IS USED BY *EPT* TO 
*         CALL THE APPROPRIATE PARAMETER PROCESSOR ROUTINE.  IF 
*         THE CONTINUATION PARAMETER IS FETCHED, THE NEXT BLOCK 
*         WILL BE READ FROM THE NETWORK.  THE COMMAND MUST MATCH THE
*         COMMAND IN THE PREVIOUS BLOCK FOR A CONTINUATION TO BE
*         VALID.
* 
*         ENTRY  (A1) IS THE ADDRESS OF THE PARAMETER LIST. 
*                (X1) IS THE FIRST ADDRESS FROM THE PARAMETER LIST. 
* 
*         PARAMETER LIST FORMAT 
*         BUFF   - ADDRESS OF THE HEADER WORD PRECEEDING THE TEXT AREA. 
*         ATTR   - ADDRESS TO RETURN THE PARAMETER ATTRIBUTE. 
*         QUAL   - ADDRESS TO RETURN THE PARAMETER QUALIFIER. 
*         TXTL   - ADDRESS TO RETURN THE LENGTH OF THE TEXT PORTION.
*         TEXT   - ADDRESS TO RETURN THE PARAMETER TEXT.
*         PARMT  - PARAMETER VALUE/PROCESSOR ADDRESS TABLE. 
* 
*                (X6) IS THE 3 CHARACTER ABRIEVIATION FOR THE COMMAND 
*                LAST RECEIVED (PARAMETERS ARE BEING PROCESSED FOR).
* 
*         EXIT   (X1) = 0, IF NO ERROR. 
*                     = MESSAGE ADDR, IF ERROR DETECTED.
*                     = -ICPM, IF ATTRIBUTE UNKNOWN.
* 
*         USES   A - 1,2,6. 
*                B - NONE.
*                X - 1,2,3,4,6,7. 
* 
*         CALLS  EPT, APFETCH.
  
  
 PRP      SUBRL  (#MB,,#QUAL,,,#TABL) 
          SA1    "MB" 
          SX7    A0 
          MX3    -12
          SA2    ICPM+3      PUT COMMAND NUMBER IN MESSAGE
          SA7    PRPA        SAVE PARAMETER LIST ADDRESS
          SA4    X1+1        GET WORD CONTAINING COMMAND
          BX2    X3*X2
          LX4    12 
          BX4    -X3*X4 
          BX6    X2+X4
          SA6    A2          STORE MODIFIED MESSAGE 
 PRP1     SA1    A0 
          APFETCH            FETCH NEXT PARAMETER 
          MX1    0
          MI     X6,PRPX     IF NO MORE ATTRIBUTES
          MX3    12 
          SA1    ICPM+3      PUT ATTRIBUTE NUMBER IN MESSAGE
          BX1    -X3*X1 
          BX7    X1+X5
          SA7    A1          REPLACE MESSAGE
          SA2    "QUAL" 
          SA1    "TABL" 
          SA2    X2          CHECK QUALIFIER
          LX2    6
          SX2    X2-1RI 
          ZR     X2,PRP1     IF IGNORE QUALIFIER
          SA2    X1 
          SA1    A0+B1       SET PARAMETER LIST ADDRESS 
          SX1    ICPM 
          BX1    -X1         COMPLEMENT MESSAGE ADDR
          RJ     =XEPT       EXECUTE PROCESSOR FROM TABLE 
          SA2    PRPA 
          NZ     X1,PRPX     IF ERROR IN PROCESS
          SA0    X2          RESET PARAMETER LIST ADDRESS 
          EQ     PRP1        FETCH NEXT PARAMETER 
  
 PRPA     BSS    1           PARAMETER LIST ADDRESS 
  
  
          QUAL   *
          SPACE  4,10 
          END 
