*DECK     PMB 
          IDENT  PMB
          TITLE  PMB - PUT MESSAGE BLOCK. 
          SST 
          SYSCOM B1 
  
  
          ENTRY  PMB
  
          COMMENT  PUT MESSAGE BLOCK. 
          COMMENT COPYRIGHT CONTROL DATA SYSTEMS INC. 1994. 
          SPACE  4,10 
**        PMB - PUT MESSAGE BLOCK.
* 
*         J. G. CLARK        80/02/07.
          SPACE  4,10 
**        COMMON DECKS. 
  
  
*CALL COMCMAC 
*CALL CMACROS 
*CALL COMCAPR 
*CALL COMCPTF 
 PMB      SPACE  4,10 
**               ROUTINE PMB NETPUTS A BLOCK OF TYPE MESSAGE WHICH IS 
*         IN THE FORMAT OF A LEVEL 7 PROTOCOL BLOCK (MUST HAVE A
*         HEADER WORD AS DEFINED FOR ACFETCH, ACSTORE, APFETCH, AND 
*         APSTORE).  THE TEXT HEADER IS BUILT IN THE SUPPLIED HEADER
*         WORD TO BE USED IN THE NETPUT CALL. 
* 
*         ENTRY  (A1) IS THE ADDRESS OF THE PARAMETER LIST. 
*                (X1) IS THE FIRST ADDRESS ON THE PARAMETER LIST. 
* 
*         PARAMETER LIST FORMAT 
*         HA     - HEADER AREA TO BE USED.
*         TA     - TEXT AREA TO BE PUT (TA-1 IS THE DEFINED TEXT HEADER)
* 
*         EXIT   NONE.
* 
*         USES   A - 2,3,5,6. 
*                B - 1. 
*                X - 2,3,5,6. 
* 
*         CALLS  NETPUT.
  
  
 PMB      SUBR               ENTRY/EXIT 
          SA2    ABN         FETCH LAST BLOCK NUMBER SENT 
          SB1    1
          NSTORE X1,ABHABT=7 SET Q-MSG TYPE BLOCK 
          NSTORE X1,ABHADR=B1 
          NSTORE X1,ABHACT=2 SET APPLICATION CHARACTER TYPE 
          SX2    X2+B1       INCREMENT BLOCK NUMBER 
          SA3    A1+B1
          NSTORE X1,ABHABN=X2 
          BX6    X2 
          SA6    A2          SAVE NEW BLOCK NUMBER
          SA3    X3-1        FETCH LENGTH IN CHARACTERS 
          NSTORE X1,ABHTLC=X3 
          RJ     =XFTUPUT    PUT THE MESSAGE BLOCK
          RJ     =XSTT       SET TIMEOUT TIME 
          SB1    1
          EQ     PMBX        RETURN 
          SPACE  4
          END 
