*DECK     PJN 
          IDENT  PJN
          TITLE  PJN - PROCESS JOBNAME PARAMETER. 
          SST 
          SYSCOM B1 
  
  
          ENTRY  PJN
  
  
          COMMENT  PROCESS JOBNAME PARAMETER. 
          COMMENT COPYRIGHT CONTROL DATA SYSTEMS INC. 1994. 
          SPACE  4,10 
**        PJN - PROCESS JOBNAME PARAMETER.
* 
*         J. G. CLARK        80/05/23.
          SPACE  4,10 
**        COMMON DECKS. 
  
  
*CALL COMCMAC 
*CALL COMCAPR 
*CALL COMCPTF 
 PDD      SPACE  4,10 
**               PJN TAKES THE JOBNAME PARAMETER TEXT AND 
*         PLACES IT INTO THE CORRELATION ACCOUNTING MESSAGE.
* 
*         ENTRY  (A1) IS THE PARAMETER LIST ADDRESS.
* 
*         PARAMETER LIST FORMAT 
*         ATTR   - ATTRIBUTE VALUE OF THIS PARAMETER. 
*         QUAL   - THE PARAMETER QUALIFIER. 
*         TXTL   - LENGTH OF THE TEXT PORTION OF THE PARAMETER. 
*         TEXT   - THE PARAMETER TEXT CONTAINING THE JOBNAME. 
* 
*         EXIT   THE ACCOUNTING MESSAGE (ALKA) HAS THE JOBNAME. 
* 
*         USES   A - 2,3,4,7. 
*                B - NONE.
*                X - 1,2,3,4,6,7. 
* 
*         CALLS  NONE.
  
  
 PJN      SUBRL  (,,,TEXT)
          SA1    TEXT        GET JOB NAME 
          RJ     =XZTB=      CHANGE ZEROS TO BLANKS 
          BX2    X6          (X2) = JOB NAME, BLANK-FILLED
          SA3    ALKA+1 
          MX6    18 
          LX2    4*6         POSITION JOBNAME FOR INSERTION 
          BX7    X6*X2
          BX6    -X6*X3 
          SA4    A3-B1
          BX7    X6+X7       MERGE JOBNAME WITH MESSAGE 
          SA7    A3 
          MX6    -24         FORM MASK FOR REMAINDER OF JOBNAME 
          BX2    -X6*X2 
          BX6    X6*X4
          BX7    X2+X6       MERGE JOBNAME WITH MESSAGE 
          SA7    A4 
          MX1    0           RETURN WITH NO ERROR 
          EQ     PJNX        RETURN 
          SPACE  4
          END 
