*DECK     OVL 
          IDENT  OVL
          ENTRY  OVL
          SST 
  
*CALL COMCMAC 
  
  
**        OVL - LOAD OVERLAY FOR QTFS.
* 
*         OVL CALLS LOADER TO LOAD THE SPECIFIED OVERLAY. 
* 
*         OVL(NAME,LIST)   SYMPL CALL FORMAT. 
* 
*         ENTRY  NAME = OVERLAY NAME. 
*                LIST = ADDRESS OF PARAMETER LIST TO BE PASSED TO 
*                       OVERLAY.
* 
*         CALLS  DXB=.
* 
*         USES   A - 1, 2, 3, 4, 6. 
*                B - 0, 1.
*                X - 1, 2, 3, 4, 5, 6.
* 
  
  
 OVL      SUBR   =
          SX6    A1+1        SAVE PARAMETER LIST ADDRESS
          SA6    OVLPARAM 
  
*         SET UP LOADER PARAMETER LIST TO LOAD OVERLAY
  
          SA3    X1 
          MX0    7*6
          BX1    X0*X3       (X1) = OVERLAY NAME
          RJ     =XCMM.LOV   CALL FOL TO LOAD OVERLAY 
          SA2    OVL         PLACE OVL RETURN AT ENTRY POINT
          BX6    X2 
          SA6    B7 
          SA1    OVLPARAM    PARAMETER LIST ADDRESS FOR OVERLAY 
          SA1    X1          (A1) = FWA OF PARAMETER LIST 
          JP     B7+1        SIMULATE RJ TO OVERLAY 
  
 OVLPARAM BSSZ   1           OVERLAY PARAMETER LIST ADDRESS 
  
          END 
