*DECK MSGLOG
USETEXT COMCBEG 
USETEXT COMCAPR 
USETEXT COMCCAE 
USETEXT COMQDEF 
    PROC MSGLOG (MSGTEXT, (MSGLENGTH)); 
      BEGIN  # MSGLOG # 
# 
**    MSGLOG     LOG MESSAGE IN DAYFILE.
* 
*     MSGLOG SENDS MESSAGE TO DAYFILE.
* 
*     PROC MSGLOG (MSGTEXT, (MSGLENGTH))
* 
*     ENTRY      MSGTEXT = MESSAGE TO BE LOGGED 
*                MSGLENGTH = LENGTH IN CHARACTERS OF MSGTEXT. 
* 
*     EXIT       MESSAGE HAS BEEN SENT TO DAYFILE.
*                MSGTEXT HAS HAD ZERO-BYTE APPENDED.
* 
*     PROCESS    IF SERVER AND MESSAGE STARTS WITH " QTF":  
*                  ADJUST MESSAGE TO "QTFS".
*                CALL ZBYTE TO ADD ZERO-BYTE
*                CALL MESSAGE TO DAYFILE MESSAGE. 
*                CALL MESSAGE TO RESTORE B DISPLAY STATUS MESSAGE.
# 
  
      BASED ARRAY MSGTEXT [0:0] S(8); 
        BEGIN 
        ITEM MSGTEXT$   C(00,00,80);  # MESSAGE TO GO TO DAYFILE #
        ITEM MSGNAME    C(00,00,04);  # PROGRAM NAME #
        END 
  
      ITEM MSGLENGTH  I;           # LENGTH OF MESSAGE IN CHARACTERS #
  
# 
****  XREF
# 
      XREF
        BEGIN 
        PROC MESSAGE;              # ISSUE DAYFILE MESSAGE #
        PROC NAME;                 # DEBUG CODE # 
        PROC ZBYTE;                # ADD ZERO BYTE TO END OF MESSAGE #
        END 
  
# 
****  XREF END
# 
  
  
  
        $BEGIN
        NAME("MSGLOG");            # DEBUG CODE # 
        $END
  
      IF QRCV AND MSGNAME EQ " QTF" 
      THEN
        BEGIN 
        MSGNAME = "QTFS"; 
        END 
  
      ZBYTE(LOC(MSGTEXT),MSGLENGTH);
      MESSAGE(MSGTEXT,0); 
      MESSAGE(MSGWFA, 1); 
  
      END  # MSGLOG # 
    TERM
