*DECK,INITS 
USETEXT COMCBEG 
USETEXT COMQDEF 
USETEXT COMQFIL 
    PROC INITS; 
      BEGIN # INITS # 
# 
**    INITS      INITIALIZE QTFS. 
* 
*     THIS PROCEDURE INITIALIZES QTFS.
* 
*     PROC INITS
* 
*     ENTRY      NONE.
* 
*     EXIT       SEE EXIT CONDITIONS FOR *INITQ*. 
* 
*     PROCESS    SET VARIABLES
*                APNAME = "QTFS". 
*                QRCV = TRUE (QTFS).
*                INITIALIZE K DISPLAY HEADER
*                CALL INITQ FOR COMMON INITIALIZATION.
# 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        ARRAY AFT$QFS [1:1] S(FILENT); ;  # FROM QFSRES # 
        PROC INITQ;                # QTFI/QTFS INITIALIZATION # 
        PROC NAME;                 # DEBUG CODE # 
        PROC CMMALF;               # ALLOCATE CMM BLOCK # 
        PROC RECOVR;               # REPRIEVE INTERFACE # 
        PROC RHCRPV;               # COMMON REPRIEVE ROUTINE #
        PROC UPKHDR;               # UPDATE K DISPLAY HEADER #
        END 
# 
****  XREF END
# 
  
      ITEM I          U;           # FOR LOOP VARIABLE #
      ITEM TEMP       U;           # TEMPORARY #
  
        $BEGIN
        NAME("INITS");             # DEBUG CODE # 
        $END
  
      QRCV = TRUE;                 # TRUE -> SERVER # 
      APNAME = "QTFS";
      MSGWFANAME = "QTFS";
      AFT[1] = LOC(AFT$QFS);       # ADDRESS OF FIRST AFT ENTRY # 
      P<FILETAB> = AFT[1];
      SLOWFOR I = 2 STEP 1 UNTIL LACNMAX
      DO
        BEGIN                      # IF NON-OVERLAYED QTFS #
        CMMALF(FILENT, 0, 0, TEMP);  # ALLOCATE AS CMM BLOCK #
        AFT[I] = TEMP;
        P<FILETAB> = AFT[I];
        END 
  
      UPKHDR;                      # UPDATE K DISPLAY HEADER #
      INITQ;                       # COMMON INITIALIZATION #
      RECOVR(RHCRPV, O"277", 0);   # ADD *RHCRPV* TO REPRIEVE LIST #
  
      END      # INITS #
    TERM
