*DECK,INITI 
USETEXT COMCBEG 
USETEXT COMCAPR 
USETEXT COMQDEF 
USETEXT COMQFIL 
USETEXT COMQKDS 
USETEXT COMQKRS 
    PROC INITI; 
      BEGIN # INITI # 
# 
**    INITI      INITIALIZE QTFI. 
* 
*     THIS PROCEDURE INITIALIZES QTFI.
* 
*     PROC INITI
* 
*     ENTRY      APNAME = "QTF".
*                QRCV = FALSE (QTFI). 
* 
*     EXIT       SEE EXIT CONDITIONS FOR *INITQ*. 
* 
*     PROCESS    GET CMM GROUP
*                INITIALIZE FILE TABLE ENTRIES
*                MODIFY K DISPLAY HEADERS FOR INITIATOR 
*                CALL UPDKDSP TO INITIATIZE K DISPLAY 
*                CALL INITQ FOR COMMON INITIALIZATION 
*                INITIALIZE CLF HEADER
*                GET REAL-TIME CLOCK
*                INITIALIZE PID/LID TABLE 
*                CALL CMPCOVS TO COMPUTE SELECTION CLASS COVER SETS 
*                IF INCLUDE-FILE SPECIFIED: 
*                  CALL INFOPE TO OPEN INCLUDE FILE.
* 
# 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        ARRAY AFT$QFI [1:ACNMAXC] S(FILENT); ;  # FROM QFIRES # 
        PROC CMMAGR;               # ASSIGN CMM GROUP # 
        PROC CMPCOVS;              # COMPUTE SEL CLASS COVER SETS # 
        PROC GNDT;                 # UPDATE PID/LID TABLE # 
        PROC ICLFHDR;              # INITIALIZE CLF HEADER #
        PROC INFOPE;               # OPEN INCLUDE FILE #
        PROC INITQ;                # QTFI/QTFS INITIALIZATION # 
        ITEM KDFSR1     C(20);     # FSI RANGE 1 #
        ITEM KDFSR2     C(20);     # FSI RANGE 2 #
        ITEM KDFSR3     C(20);     # FSI RANGE 3 #
        ITEM KDFSR4     C(20);     # FSI RANGE 4 #
        ITEM KDFSR5     C(20);     # FSI RANGE 5 #
        ITEM KDFSR6     C(20);     # FSI RANGE 6 #
        ITEM KDFSR7     C(20);     # FSI RANGE 7 #
        PROC NAME;                 # DEBUG CODE # 
        PROC RSECS;                # GET REAL-TIME CLOCK #
        PROC UPDKDSP;              # UPDATE K DISPLAY # 
        END 
# 
****  XREF END
# 
  
      ITEM I          U;           # FOR LOOP VARIABLE #
      ITEM LOCOFAFT   U;           # AFT ENTRY ADDRESS #
  
        $BEGIN
        NAME("INITI");             # DEBUG CODE # 
        $END
  
      CMMAGR(0, CMMN);             # GET GROUP NAME # 
      LOCOFAFT = LOC(AFT$QFI);     # ADDRESS OF FIRST AFT ENTRY # 
      FOR I = 1 STEP 1 UNTIL LACNMAX
      DO
        BEGIN 
        AFT[I] = LOCOFAFT;         # POINTER TO AFT ENTRY # 
        P<FILETAB> = LOCOFAFT;
        LOCOFAFT = LOCOFAFT + FILENT; 
        END 
  
      KL$TISENT = "SENT";          # *RCVD*       -> *SENT*       # 
      KL$LN24CMD = " COMMAND-";    # *          * -> * COMMAND- * # 
      KL$INIT = "INITIATOR";       # *SERVICER*   -> *INITIATOR*  # 
  
    CONTROL IFEQ OS$NOS;
      KR$FSR[1] = KDFSR1; 
      KR$FSR[2] = KDFSR2; 
      KR$FSR[3] = KDFSR3; 
      KR$FSR[4] = KDFSR4; 
      KR$FSR[5] = KDFSR5; 
      KR$FSR[6] = KDFSR6; 
      KR$FSR[7] = KDFSR7; 
      KR$TBUF = LOC(KR$DT);        # RIGHT SCREEN DISPLAY TITLE # 
      KDISKEY = LOC(KDISINPT);     # KEYBOARD INPUT BUFFER #
      KDISRSC = LOC(KR$FWA);       # RIGHT SCREEN BODY #
    CONTROL ENDIF;
  
      UPDKDSP;                     # UPDATE K DISPLAY # 
      INITQ;                       # COMMON INITIALIZATION #
  
    CONTROL IFEQ OS$NOS;
      CLFHDR$PID = HID;            # PUT PID IN CLF HEADER #
      ICLFHDR(LOC(CLFHDR$TIE),CLFHDR$TIL); # SYSTEM LABEL IN HEADER # 
    CONTROL ENDIF;
  
      RSECS(TIM);                  # SET REAL TIME CLOCK #
      GNDT;                        # INITIALIZE PID/LID TABLE # 
      CMPCOVS;                     # COMPUTE SEL CLASS COVER SETS # 
      IF INCLFILE NE " "           # IF INCLUDE FILE SPECIFIED #
      THEN
        BEGIN 
        INFOPE(INCLFILE);          # OPEN INCLUDE FILE #
        END 
  
      END      # INITI #
    TERM
