*DECK,INFCLO
USETEXT COMCBEG 
USETEXT COMQDEF 
USETEXT COMQCMD 
      PROC INFCLO;
        BEGIN    # INFCLO # 
# 
**    INFCLO     CLOSE INCLUDE FILE.
* 
*     CLOSES THE CURRENT INCLUDE FILE.
* 
*     PROC INFCLO 
* 
*     ENTRY      READINGINF = TRUE, IF INCLUDE FILE IS OPEN 
*                RETURNINF = TRUE, IF CURRENT FILE SHOULD BE RETURNED.
* 
*     EXIT       READINGINF = FALSE 
*                RETURNINF = FALSE. 
* 
*     PROCESS    IF READING-FILE: 
*                  IF FET BUSY: 
*                    WAIT FOR FET COMPLETE. 
*                  IF RETURN-FILE:  
*                    RETURN FILE. 
*                  RELEASE CMM BLOCK. 
*                CLEAR READING-FILE 
*                CLEAR RETURN-FILE. 
* 
# 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        FUNC FREECMM   U;          # RELEASE CMM BLOCK #
        PROC NAME;                 # DEBUG CODE # 
        PROC RECALL;               # ISSUE RECALL REQUEST # 
        PROC RETERN;               # ISSUE RETURN FUNCTION #
        END 
  
# 
****  XREF END
# 
  
        $BEGIN
        NAME("INFCLO");            # DEBUG CODE # 
        $END
  
      IF READINGINF                # IF READING FILE #
      THEN
        BEGIN 
        P<FET> = INFFET;
        RECALL(FET);
        IF RETURNINF
        THEN
          BEGIN 
          RETERN(FET, 1);          # RETURN FILE #
          END;
  
        INFFET = FREECMM(INFFET); 
        END 
  
      INCLFILE = " "; 
      READINGINF = FALSE; 
      RETURNINF = FALSE;
  
      END  # INFCLO # 
    TERM
