*DECK ICLFHDR 
          IDENT  ICLFHDR
          TITLE  ICLFHDR - INITIALIZE NOS CLF HEADER. 
          ENTRY  ICLFHDR
          SST 
*CALL COMCMAC 
          SPACE  4,10 
**        ICLFHDR - INITIALIZE NOS CLF HEADER.
* 
*         ICLFHDR IS CALLED TO GET THE SYSTEM LABEL AND DATE AND PLACE
*         THEM IN THE CONNECTION LOG FILE HEADER. 
* 
*         ICLFHDR(FWAHDR,LENGTHHDR) 
* 
*                FWAHDR = FWA OF ARRAY TO RECEIVE HEADER
*                LENGTHHDR = NUMBER OF WORDS TO READ
*                            DATE IS RETURNED AT FWAHDR+LENGTHHDR 
          SPACE  4,10 
 ICLFHDR  SUBR
 NOS      IFEQ   OS$NOS 
          SB1    1
          SA2    A1+B1
          SA4    X1          (X4) = FWA OF TITLE
          MX6    60          (X6) = -0
          SA6    X4          STORE AT FWA FOR RSB 
          SA5    X2          (X5) = LENGTH
          BX6    X5 
          IF     -DEF,SYTL,1
 SYTL     EQU    34B
          SX2    SYTL        FWA OF SYSTEM LABEL IN CMR 
          LX6    36 
          LX2    18 
          BX6    X6+X4
          BX6    X6+X2       (X6) = 12/0,12/LENGTH,18/SYTL,18/FWA 
          SA6    ICLA        RSB PARAMETER BLOCK
          SYSTEM RSB,RCL,A6 
          SB2    X4          (B2) = FWA OF HEADER 
          SB3    X5-1        (B3) = OFFSET
          DATE   B2+X5       STORE DATE 
  
 ICL1     SA1    B2+B3       GET NEXT WORD IN TITLE 
          RJ     =XZTB=      CHANGE ZEROS TO BLANKS 
          SA6    A1          REPLACE
          SB3    B3-B1       DECREMENT OFFSET 
          PL     B3,ICL1     IF MORE TO BLANK-FILL
 NOS      ENDIF 
  
          EQ     ICLFHDR     RETURN 
  
 ICLA     BSS    1           PARAMETER BLOCK
  
          END 
