*DECK GENERT
USETEXT COMCBEG 
USETEXT COMQDEF 
USETEXT COMQDSP 
USETEXT COMQFIL 
USETEXT COMQQAC 
    PROC GENERT;
      BEGIN  # GENERT # 
# 
**    GENERT     GENERATE EXPLICIT ROUTING TEXT.
* 
*     ENTRY      QACB = ACQUIRED FILE ENTRIES.
* 
*     EXIT       FILEERT = FWA OF TEXT BUFFER OR ZERO, IF NONE. 
# 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        PROC MESSAGE;              # ISSUE DAYFILE MESSAGE #
        PROC NAME;
        PROC TXTPUT;               # STORE ROUTING TEXT # 
        END 
  
# 
****  XREF END
# 
  
      ITEM ERTBUF     U;           # POINTER TO BUFFER #
      ITEM ERTLENGTH  U;           # LENGTH OF TEXT # 
      ITEM ERTTXT     U;           # POINTER TO TEXT #
  
        $BEGIN
        NAME( "GENERT");
        $END
  
      ERTBUF = 0; 
  
    CONTROL IFEQ OS$NOS;
      ERTLENGTH = QACBELN;
      ERTTXT = LOC(QACBERT);
    CONTROL ENDIF;
  
    CONTROL IFEQ OS$NOSBE;
      ERTLENGTH = 0;
      IF QACRTR                    # IF ROUTING TEXT PRESENT #
      THEN
        BEGIN 
        P<DSPXPB> = QACXPBP;
        ERTLENGTH = DSPXELC;
        ERTTXT = LOC(DSPXERTFWA); 
        END 
  
    CONTROL ENDIF;
  
      IF ERTLENGTH NE 0            # IF TEXT PRESENT #
      THEN
        BEGIN 
        TXTPUT(ERTBUF, ERTTXT, ERTLENGTH);
  
          $BEGIN
          P<FET> = ERTTXT;
          MESSAGE(FET, 0);
          $END
  
        END 
  
      FILEERT = ERTBUF; 
  
      END  # GENERT # 
    TERM
