*DECK FACDTB
USETEXT COMCBEG 
    FUNC FACDTB (TEXT, TEXTL) U;
      BEGIN 
# 
**    FACDTB - CONVERT FACILITIES ATTRIBUTE DISPLAY CODE TO BIT STRING. 
* 
*     FUNC       FACDTB (TEXTA, TEXTL) U
* 
*     ENTRY      TEXT   = FACILITIES TEXT 
*                TEXTL  = NUMBER OF CHARACTERS (0 - 240). 
* 
*     EXIT       FACDTB = INTEGER BIT STRING. BITS NUMBERED FROM LEFT:  
*                         BIT  0    SET IF INVALID CHARACTER, 
*                                    OR IF TEXTL .GT. MAXTEXTL
*                         BITS 1-36 SET FOR TEXT CHARACTERS A-9.
# 
  
      ITEM TEXT       U;
      ITEM TEXTL      I;
  
      DEF  BITERR     #   0 #;
      DEF  MAXTEXTL   # 240 #;
  
      ARRAY [0:0] S(1); 
        BEGIN 
        ITEM DUMC       C(00,00,01);
        ITEM DUMU       U(00,00,06);
        END 
  
      BASED ARRAY TEXTA [0:0] S(1); 
        BEGIN 
        ITEM TEXTC      C(00,00,240); 
        END 
  
      ITEM BITSTR     U;
      ITEM I          U;
      ITEM TC         I;
  
      P<TEXTA> = LOC(TEXT); 
      BITSTR = 0; 
      TC = TEXTL; 
      IF TC GR MAXTEXTL 
      THEN
        BEGIN 
        B<BITERR,1>BITSTR = 1;
        END 
  
      ELSE
        BEGIN 
        TC = TC-1;
        FOR I = 0 STEP 1 UNTIL TC 
        DO
          BEGIN 
          DUMC = C<I,1>TEXTC; 
          IF   (DUMU EQ 0)
            OR (DUMU GR 36) 
          THEN
            BEGIN 
            DUMU = BITERR;
            END 
  
          B<DUMU,1>BITSTR = 1;
          END 
        END 
  
      FACDTB = BITSTR;
      END  # FACDTB # 
  
    TERM; 
