*DECK     EPT 
          IDENT  EPT
          TITLE  EPT - EXECUTE PROCESSOR FROM TABLE.
          SST 
          SYSCOM B1 
  
  
          ENTRY  EPT
  
  
  
          COMMENT  EXECUTE PROCESSOR FROM TABLE.
          COMMENT COPYRIGHT CONTROL DATA SYSTEMS INC. 1994. 
          SPACE  4,10 
**        EPT - EXECUTE PROCESSOR FROM TABLE. 
* 
*         J. G. CLARK        80/01/03.
          SPACE  4,10 
**        COMMON DECKS. 
  
  
 EPT      SPACE  4,10 
**               EPT WILL CALL A SUBROUTINE FROM A LIST OF ROUTINE
*         ADDRESSES DEPENDING ON A SUPPLIED VALUE.  ENTRY 
*         TO THE ROUTINE IS AS IF CALLED FROM EPT-S CALLER. 
*         THE LIST OF VALUES AND ROUTINE ADDRESSES IS SCANNED 
*         FOR A MATCH WITH THE CALLING VALUE.  IF NO MATCH IS 
*         FOUND EPT EXITS TO THE CALLER (X1 UNCHANGED). 
* 
*         ENTRY  (A2) IS THE ADDRESS OF THE TABLE OF VALUES/ADDRESSES.
*                (X6) IS THE VALUE TO MATCH WITH. 
* 
*         TABLE FORMAT
**T TABLE 42/ VALUE,18/ ADDR
* 
*         VALUE  - THE VALUE TO MATCH AGAINST.
*         ADDR   - ADDRESS TO BEGIN EXECUTION AT (ENTRY+1). 
* 
*         EXIT   EXIT IS TO ADDR IF A VALUE MATCH IS FOUND. 
* 
*         USES   A - 2,3,6. 
*                B - 2. 
*                X - 2,3,6. 
* 
*         CALLS  NONE.
  
  
 EPT      SUBR               ENTRY/EXIT 
 EPT1     ZR     X2,EPTX     IF NO MATCH FOUND
          BX3    X2 
          AX3    18 
          IX3    X3-X6
          ZR     X3,EPT2     IF MATCH FOUND 
          SA2    A2+B1
          EQ     EPT1        CONTINUE SEARCH
  
 EPT2     SA3    EPTX        GET RETURN ADDRESS 
          SB2    X2 
          BX6    X3 
          SA6    B2-B1       STORE RETURN ADDRESS 
          JP     B2          ENTER PROCESSOR
          SPACE  4
          END 
