*DECK DSPQFIL                      24JUL81
USETEXT COMCBEG 
USETEXT COMCAPR 
USETEXT COMCCAE 
USETEXT COMQDEF 
USETEXT COMQFIL 
USETEXT COMQNET 
    PROC DSPQFIL; 
      BEGIN    # DSPQFIL #
# 
**    DSPQFIL    DISPOSE OF QUEUE FILES.
* 
*     DSPQFIL EVICTS OR REQUEUES (RETURNS TO THE I/O QUEUE) A FILE THAT 
*     HAS BEEN EITHER TRANSFERRED OR REJECTED BY ALL REMOTE SYSTEMS.
* 
*     PROC DSPQFIL
* 
*     ENTRY      ACN = INDEX OF FILE TO EVICT RETURN: 
*                FILEANW = TRUE (EVICT) OR FALSE (REQUEUE). 
* 
*     EXIT       IF FILE EVICTED OR REQUEUED -- 
*                FILELFN = 0 (FILE NAME). 
*                FILEJBN = 0 (JOB NAME).
* 
*     PROCESS    CALL RTNFIL TO REQUEUE OR EVICT FILE.
*                CLEAR AFT ENTRY. 
# 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        PROC ACTLOG;
        PROC CONLOG;
        PROC NAME;                 # DEBUG CODE # 
        PROC RTNFIL;
        PROC TXTREL;               # RELEASE ROUTING TEXT BUFFERS # 
        END 
# 
****  XREF END
# 
  
  
  
      ITEM EVICT      B;
      DEF LEMSGEVT   #08#;
      ITEM EMSGEVT    C(LEMSGEVT) = "EVICTED."; 
  
      DEF LEMSGRET   #09#;
      ITEM EMSGRET    C(LEMSGRET) = "REQUEUED.";
  
  
      $BEGIN
      NAME("DSPQFIL");             # DEBUG CODE # 
      $END
  
          IF FILEANW               # IF EVICTING FILE # 
          THEN
            BEGIN 
            EVICT = TRUE;          # SET EVICT FILE FLAG #
            CONLOG(LOC(EMSGEVT),LEMSGEVT);
            ACTLOG;                # LOG ACCOUNTING MESSAGES #
            END 
  
          ELSE                     # RETURN FILE TO QUEUE # 
            BEGIN 
            EVICT = FALSE;         # SET RETURN FILE FLAG # 
            CONLOG(LOC(EMSGRET),LEMSGRET);
            END 
  
          RTNFIL (FILELFNC, EVICT); 
          TXTREL;                  # RELEASE TEXT BUFFERS # 
          FILEERT = 0;
          FILEIRT = 0;
          FILESRT = 0;
          FILELFN = 0;             # CLEAR LFN #
          FILEJBN = 0;             # CLEAR JOBNAME #
  
      END  # DSPQFIL #
    TERM
