*DECK     DDC 
          IDENT  DDC
          TITLE  DDC - DATA DECLARATION CONVERSION. 
          SST 
          SYSCOM B1 
          ENTRY  DDC
  
*COMMENT  DDC - DATA DECLARATION CONVERSION.
          COMMENT COPYRIGHT CONTROL DATA SYSTEMS INC. 1994. 
          SPACE  4,10 
**        DDC - DATA DECLARATION CONVERSION.
* 
*         J. G. CLARK        80/04/25.
          SPACE  4,10 
**        COMMON DECKS. 
* 
*         COMCMAC - CPU SYSTEM MACROS.
  
  
 DDC      SPACE  4,10 
**               DDC CONVERTS THE TWO CHARACTER DATA DECLARATION
*         TO A VALUE TO BE USED BY *NETXFR*.
* 
*         CALL FORMAT 
*                IXFR = DDC (DD)
* 
*         ENTRY  (A1) = PARAMETER LIST ADDRESS
* 
*         PARAMETER LIST FORMAT 
*         DD     - DATA DECLARATION, TWO CHARACTERS LEFT JUSTIFIED. 
* 
*         EXIT   (X6) = CORRESPONDING VALUE FOR AIP/FIP *NETXFR* DD:  
*                            UH -> 0
*                            UU -> 1
*                            US -> 2
*                            C6 -> 3
*                            C8 -> 4
*                     = NEGATIVE IF NO MAPPING FOUND. 
* 
*         USES   A - 1,2. 
*                B - 2. 
*                X - 0,1,2,3,6. 
* 
*         CALLS  NONE.
  
  
 DDC      SUBR               ENTRY/EXIT 
          SA1    X1 
          SB2    4           SET MAXIMUM VALUE
          MX0    12 
          SA2    DDCA        GET MAP
          SX6    B2 
          BX1    X0*X1       CHECK ONLY LEFT 2 CHARACTERS 
 DDC1     BX3    X0*X2
          BX3    X1-X3       COMPARE CHARACTERS 
          ZR     X3,DDCX     IF MATCH FOUND 
          LX2    12 
          SB2    B2-1 
          SX6    B2          SET NEW VALUE
          PL     X6,DDC1     IF POSSIBLE MATCH LEFT 
          EQ     DDCX        EXIT WITH NO MATCH FOUND 
  
 DDCA     DATA   10HC8C6USUUUH
          SPACE  4
          END 
