*DECK CONENDR                      22JUL81
USETEXT COMCBEG 
USETEXT COMCAPR 
USETEXT COMCCAE 
USETEXT COMQDEF 
USETEXT COMQFIL 
USETEXT COMQNET 
    PROC CONENDR; 
      BEGIN    # CONENDR #
# 
**    CONENDR    PROCESS CON/END RESPONSE.
* 
*     CONENDR DISPOSES OF A FILE BEING TRANSFERRED DEPENDING ON ITS 
*     STATUS. 
* 
*     PR0C CONENDR
* 
*     ENTRY      ACN = APPLICATION CONNECTION NUMBER. 
*                QRCV  = QTFI/QTFS INDICATOR. 
* 
*     EXIT       AFT ENTRY STATUS UPDATED.
* 
*     PROCESS    IF AFT ENTRY STATUS INDICATES ERROR: 
*                  SEND MESSAGE 13. 
*                IF FILE TRANSFERRED: 
*                  SET STATUS TO TRANSFER SUCCESSFUL. 
*                ELSE:  
*                  SET STATUS TO TRANSFER TERMINATED. 
# 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        PROC CONLOG;
        PROC NAME;                 # DEBUG CODE # 
        PROC RELNTA;               # RELEASE ALL NETWORK BUFFERS #
        END 
# 
****  XREF END
# 
  
  
  
      DEF LEMSGCE    #26#;
      ARRAY EMSGCE     S(3);
        BEGIN 
        ITEM $DCE       C(00,00,LEMSGCE) =
                 ["CONNECTION TO XXX YYYYYYYY"];
        ITEM EMSGCEPI   C(01,24,03);
        ITEM EMSGCEAE   C(01,48,08);
        END 
  
      DEF LEMSGEFT   #23#;
      ITEM EMSGEFT    C(LEMSGEFT) = "ERROR IN FILE TRANSFER.";
  
        $BEGIN
        NAME("CONENDR");             # DEBUG CODE # 
        $END
  
      IF FILELFN NE 0              # IF FILE STILL PRESENT #
        AND FILECER                # AND STATUS ERROR # 
      THEN
        BEGIN 
        CONLOG(LOC(EMSGEFT),LEMSGEFT);
        END 
  
      IF FILEBRK                   # IF FC/BRK RECEIVED # 
        OR (FILE61 EQ 0)           # OR ETPR NOT SENT/RECEIVED #
      THEN
        BEGIN 
        EMSGCEAE = "ABORTED.";
        END 
  
      ELSE
        BEGIN 
        EMSGCEAE = "ENDED.";
        END 
  
      EMSGCEPI = FILECPDC;
      CONLOG(LOC(EMSGCE),LEMSGCE);
      IF FILELFN NE 0              # IF FILE STILL PRESENT #
        AND NOT FILECER            # AND NO ERROR # 
        AND (FILE1 NE 0)           # AND FILE TRANSFERRED # 
        AND (FILE3 NE 0)
        AND (FILE5 NE 0)           # AND STOPR RECEIVED # 
      THEN
        BEGIN 
        FILEFTS = FTS$CMPOK;
        END 
  
      ELSE
        BEGIN 
        FILEFTS = FTS$CMPCNT; 
        END 
  
      RELNTA(FILENHA);             # RELEASE ALL NETPUT BUFFERS # 
      FILENHA = 0;
  
      END      # CONENDR #
    TERM
