*DECK CONENDM                      26MAY81
USETEXT COMCBEG 
USETEXT COMCAPR 
USETEXT COMCCAE 
USETEXT COMQDEF 
USETEXT COMQFIL 
USETEXT COMQNET 
    PROC CONENDM; 
      BEGIN    # CONENDM #
# 
**    CONENDM    BUILD AND SEND CON/END NETWORK MESSAGE.
* 
*     CONENDM RELEASES A CONNECTION FOR QTF OR QTFS.
* 
*     PR0C CONENDM
* 
*     ENTRY      ACN = APPLICATION CONNECTION NUMBER. 
*                NHA, NTA  = NETWORK MESSAGE HEADER, BUFFER.
* 
*     EXIT       AFT ENTRY STATUS UPDATED.
*                FILECE = FILECB = TRUE (CONNECTION ENDED). 
* 
*     PROCESS    IF CONNECTION ACTIVE:  
*                  CALL NETPUT (SEND CON/END MESSAGE) 
*                  UPDATE AFT ENTRY.
# 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        PROC FTUPUT;               # OUTPUT NETWORK MESSAGE # 
        PROC NAME;                 # DEBUG CODE # 
        PROC NSTORE;               # BUILD NETWORK MESSAGE #
        PROC RELNTA;               # RELEASE ALL NETWORK BUFFERS #
        END 
# 
****  XREF END
# 
  
  
        $BEGIN
        NAME("CONENDM");             # DEBUG CODE # 
        $END
  
        IF FILECM                  # CONNECTION MADE #
          AND NOT FILECE           # AND NOT ENDED #
        THEN
          BEGIN 
          NTAWD[1]=0;                  # CLEAR TEXT AREA #
          NTAWD[2]=0; 
          NSTORE(NTA,$PFCSFC,CONEND);  # STORE CON/END FUNCTION CODE #
          NSTORE(NTA,$CONACN,ACN);     # STORE ACN #
          NHA=SUPHDR+1;                # STORE MESSAGE TYPE # 
          FTUPUT(NHA,NTA);         # SEND MESSAGE # 
          RELNTA(FILENHA);
          FILENHA = 0;
          FILECB  = TRUE;          # SET CONNECTION BROKEN #
          FILECE  = TRUE;          # SET CON/END SENT # 
          FILEFTS = FTS$WNMSG;
          FILETIM = TIMT; 
          END 
      END      # CONENDM #
    TERM
