*DECK,CMDSTA
USETEXT COMCBEG 
USETEXT COMQDEF 
USETEXT COMQKDS 
USETEXT COMQPAR 
    PROC CMDSTA;
      BEGIN  # CMDSTA # 
# 
**    CMDSTA     PROCESS *STATUS* COMMAND.
* 
*     PROCESSES THE OPERATOR *STATUS* COMMAND.
* 
*     SCHED,PID 
*     SCHED,SC
*     SCHED,TRANSFER
* 
*     PROC CMDSTA 
* 
*     ENTRY      PARMS = PARSED COMMAND PARAMETERS. 
* 
*     EXIT       PARAMETERS PROCESSED 
*                K DISPLAY ORDINAL SET. 
* 
# 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        PROC NAME;                 # DEBUG CODE # 
        END 
  
# 
****  XREF END
# 
  
  
      ARRAY FP [KDIS"PID":KDIS"LAST"] S(1); 
        BEGIN 
        ITEM FP$KEY     C(00,00,07) = 
          [ "PID"    , "SC"     , "TRANSFE", "UNKNOWN"];
        ITEM FP$MIN     U(00,42,06) = 
          [         1,         1,         1,         1];
        ITEM FP$UNKNOWN B(00,48,01) = 
          [FALSE     ,FALSE     ,FALSE     ,TRUE      ];
        ITEM FP$KDIS    S:KDIS(00,54,06) =
          [S"PID"    ,S"SC"     ,S"TRANSFE",S"HELP"   ];
        END 
  
      ITEM FPORD      S:KDIS;      # PARAMETER ORDINAL #
  
        $BEGIN
        NAME("CMDSTA");            # DEBUG CODE # 
        $END
  
      IF (PARM$PCNT NE 1) 
        OR (PARM$VTYPE[1] NE S"KEYWORD")
        OR (PARM$PLEN[1] LT 1)
      THEN
        BEGIN 
        KDISORD = S"HELP";
        PARM$STAT = S"PARMERR"; 
        PARM$ECOL = PARM$COL[2];
        RETURN; 
        END 
  
      IF PARM$PLEN[1] GT 7
      THEN
        BEGIN 
        PARM$PLEN[1] = 7; 
        END 
  
      FP$KEY[KDIS"LAST"] = PARM$KEY[PARM$PCNT]; 
      FPORD = S"PID"; 
      ASLONGAS (C<0,PARM$PLEN[PARM$PCNT]>FP$KEY[FPORD]
                  NE C<0,PARM$PLEN[PARM$PCNT]>PARM$KEY[PARM$PCNT])
            OR (PARM$PLEN[PARM$PCNT] LT FP$MIN[FPORD])
      DO
        BEGIN 
        FPORD = FPORD + 1;
        END 
  
      KDISORD = FP$KDIS[FPORD]; 
      KS$UPDATE[KDISORD] = TRUE;
      IF FP$UNKNOWN[FPORD]
      THEN
        BEGIN 
        PARM$STAT = S"PARMERR"; 
        PARM$ECOL = PARM$COL[PARM$PCNT];
        END 
  
      END  # CMDSTA # 
    TERM
