*DECK CMDPUT                       26MAY81
USETEXT COMCBEG 
USETEXT COMCAPR 
USETEXT COMCCAE 
USETEXT COMQDEF 
USETEXT COMQFIL 
USETEXT COMQNET 
      PROC CMDPUT;
        BEGIN    # CMDPUT # 
# 
**    CMDPUT     SEND LEVEL 7 NETWORK MESSAGE.
* 
*     CMDPUT LINKS THE CHAIN OF BUFFERS FOR THE LEVEL 7 MESSAGE 
*     TO THE END OF THE NETPUT QUEUE. 
* 
*     PROC CMDPUT 
* 
*     ENTRY      ACN = APPLICATION CONNECTION NUMBER. 
*                FILEWHA = FWA OF LEVEL 7 CMD BUFFER CHAIN. 
*                FILENHA = FWA OF MESSAGE BUFFER. 
* 
*     EXIT       AFT ENTRY STATUS UPDATED.
*                FILENHA = MESSAGE BUFFERS CHAINED TO TAIL. 
*                FILEWHA = 0. 
* 
*     PROCESS    CALL SETNTA TO FIND END OF NHA (NETPUT) CHAIN. 
*                LINK HEAD OF CURRENT COMMAND CHAIN (WHA) TO
*                  END OF NHA CHAIN.
*                IF NETPUT CHAIN WAS EMPTY: 
*                  CALL PUTNTA TO NETPUT FIRST BLOCK. 
*                CLEAR WHA. 
# 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        PROC NAME;                 # DEBUG CODE # 
        PROC PUTNTA;
        PROC SETNTA;
        END 
# 
****  XREF END
# 
  
  
      $BEGIN
      NAME ("CMDPUT");             # DEBUG CODE # 
      $END
  
      IF FILENHA EQ 0              # IF NO BLOCKS OUTSTANDING # 
      THEN
        BEGIN 
        FILENHA = FILEWHA;
        PUTNTA;                    # NETPUT FIRST BLOCK # 
        END 
  
      ELSE
        BEGIN 
        SETNTA(FILENHA);           # FIND LAST BUFFER IN CHAIN #
        NHA$LNK = FILEWHA;         # LINK TO END OF CHAIN # 
        END 
  
      FILEWHA = 0;
  
      END      # CMDPUT # 
    TERM
