*DECK,CKEVNTI 
USETEXT COMCBEG 
USETEXT COMQDEF 
USETEXT COMQNET 
USETEXT COMQSCH 
      PROC CKEVNTI; 
        BEGIN    # CKEVNTI #
# 
**    CKEVNTI    CHECK FOR INITIATOR EVENT. 
* 
*     CKEVNTI SCANS FOR EVENTS AND CALLS THE APPROPRIATE PROCESSOR
*     FOR EACH.  IT IS PRIMARILY RESPONSIBLE FOR ADVANCING FILE 
*     TRANSFERS.
* 
*     PROC CKEVNTI
* 
*     ENTRY      NONE.
* 
*     EXIT       TIMNXTEVT UPDATED (SECONDS UNTIL NEXT TIMEOUT).
* 
*     PROCESS    IF CONNECTIONS ACTIVE OR MESSAGE AVAILABLE (NSUP): 
*                  CALL NMSG TO CHECK FOR NETWORK MESSAGE 
*                ELSE:  
*                  (IF NONE ACTIVE, LET NETWAIT UPDATE NSUP). 
*                IF NOT SHUTDOWN: 
*                  FOR EACH CONNECTION SLOT:  
*                    CALL SFILI TO CHECK/ADVANCE CURRENT STATE. 
*                  CALL OPRINPT TO CHECK FOR OPERATOR INPUT.
# 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        PROC NAME;                 # DEBUG CODE # 
        PROC NMSG;                 # OBTAIN AND PROCESS NETWORK MSG # 
        PROC OPRINPT;              # PROCESS OPERATOR INPUT # 
        PROC SFILI;                # ADVANCE TRANSFER STATE # 
        END 
  
# 
****  XREF END
# 
  
        $BEGIN
        NAME("CKEVNTI");           # DEBUG CODE # 
        $END
  
      IF (ACNNO GT 0)              # IF CONNECTIONS ACTIVE #
        OR (NSUPIORS)              #   OR NETWORK MESSAGE AVAILABLE # 
      THEN
        BEGIN 
        NMSG;                      # CHECK FOR NETWORK MESSAGE #
        END 
  
      IF SHUTDOWN 
      THEN
        BEGIN 
        TIMNXTEVNT = 0; 
        RETURN;                    # EXIT IF SHUTDOWN # 
        END 
  
      TIMNXTEVNT = O"7777";        # ASSUME NO TIMEOUTS PENDING # 
      SLOWFOR ACN = 1 STEP 1 UNTIL LACNMAX
      DO
        BEGIN 
        SFILI;                     # UPDATE AND ADVANCE AFT ENTRY # 
        END 
  
      OPRINPT;                     # CHECK FOR OPERATOR INPUT # 
  
      END  # CKEVNTI #
    TERM
