*DECK BCMTXT
USETEXT COMCBEG 
USETEXT COMCCAE 
USETEXT COMQDEF 
USETEXT COMQNET 
    PROC BCMTXT ((TXTADR), (TXTATRB));
      BEGIN    # BCMTXT # 
# 
**    BCMTXT     STORE ROUTING TEXT ATTRIBUTE IN RFT. 
* 
*     BCMTXT IS CALLED BY BCM00 TO STORE EACH OF THE ROUTING
*     TEXTS IN THE RFT COMMAND. 
* 
*     PROC BCMTXT ((TXTADR), (TXTATRB)) 
* 
*     ENTRY      TXTADR = FWA OF ROUTING TEXT BUFFER (OR ZERO). 
*                TXTATRB = ATTRIBUTE NUMBER OF THIS TEXT. 
*                NTA = POINTER TO RFT COMMAND BEING BUILT.
* 
*     EXIT       ROUTING TEXT STORED IN RFT (IF TEXT EXISTS). 
* 
*     PROCESS    IF ROUTING TEXT EXISTS:  
*                  CALL TXTGET TO GET POINTER TO TEXT.
*                  CALL APSTOR TO STORE TEXT IN RFT.
# 
  
      ITEM TXTADR     U;           # FWA OF TEXT BUFFER # 
      ITEM TXTATRB    U;           # ATTRIBUTE NUMBER # 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        PROC APSTOR;               # STORE ATTRIBUTE #
        PROC NAME;                 # DEBUG CODE # 
        PROC TXTGET;               # GET POINTER TO TEXT #
        END 
# 
****  XREF END
# 
  
      ITEM TXTLNG     U;           # LENGTH OF TEXT # 
      ITEM TXTPTR     U;           # POINTER TO TEXT #
      BASED ARRAY TEXT S(1); ;     # POINTER TO TEXT #
  
        $BEGIN
        NAME("BCMTXT");            # DEBUG CODE # 
        $END
  
      IF TXTADR NE 0               # IF TEXT BUFFER EXISTS #
      THEN
        BEGIN 
        TXTGET(TXTADR, TXTPTR, TXTLNG);  # GET POINTER TO TEXT #
        P<TEXT> = TXTPTR; 
        APSTOR(NTA$B, TXTATRB, ATQ$S, TXTLNG, TEXT);
        END;
  
      END      # BCMTXT # 
    TERM
