*DECK ACTLOG
USETEXT COMCBEG 
USETEXT COMCAPR 
USETEXT COMCCAE 
USETEXT COMQDEF 
USETEXT COMQFIL 
USETEXT COMQNET 
    PROC ACTLOG;
      BEGIN    # ACTLOG # 
# 
**    ACTLOG     LOG ACCOUNTING MESSAGES. 
* 
*     ACTLOG IS CALLED TO ISSUE CROSS-CORRELATION MESSAGES TO THE 
*     ACCOUNT DAYFILE WHEN A TRANSFER IS COMPLETE.
* 
*     PROC ACTLOG 
* 
*     ENTRY      ACN = AFT INDEX
*                FILESIZ = FILE SIZE IN PRUS
* 
*     EXIT       ACCOUNTING MESSAGES ISSUED.
* 
*     PROCESS    BUILD MESSAGES 
*                CALL MESSAGE TO ISSUE TO DAYFILE.
# 
  
# 
****  XREF
# 
      XREF
        BEGIN 
        PROC MESSAGE;              # ISSUE DAYFILE MESSAGE #
        PROC NAME;                 # DEBUG CODE # 
        FUNC YCDZ       C(10);     # CONVERT TO DECIMAL DISPLAY CODE #
        FUNC XSFW       C(10);     # CONVERT ZEROS TO BLANKS #
        END 
  
# 
****  XREF END
# 
  
  
    CONTROL IFEQ OS$NOS;
      DEF AJSNMSGDES #O"12"#; 
      ARRAY ACLK       S(5);
        BEGIN 
        ITEM $DACLK     C(00,00,40) = 
                 ["LJSN     OACLK, JOBNAME, PID, LID.       "]; 
        ITEM $DACLKZ    U(04,00,60) = [0];
        ITEM ACLK$LN    C(00,00,04);
        ITEM ACLK$SC    U(00,54,06);
        ITEM ACLK$RN    C(01,36,07);
        ITEM ACLK$PID   C(02,30,03);
        ITEM ACLK$LID   C(03,00,03);
        ITEM ACLK$ERR   C(03,18,07);
        END 
  
      ARRAY UCLS       S(4);
        BEGIN 
        ITEM $DUCLS     C(00,00,35) = 
                 ["LJSN     OUCLS, TY, XXXXXX.XXXKUNS."]; 
        ITEM $DUCLSZ    U(03,30,30) = [0];
        ITEM UCLS$LN    C(00,00,04);
        ITEM UCLS$SC    U(00,54,06);
        ITEM UCLS$TY    C(01,36,02);
        ITEM UCLS$KUNU  C(02,00,06);
        ITEM UCLS$KUNL  C(02,42,03);
        END 
  
      ARRAY S(1); 
        BEGIN 
        ITEM KUN        C(00,00,09);
        ITEM KUNU       C(00,00,06);
        ITEM KUNL       C(00,36,03);
      END 
  
    CONTROL ENDIF;
  
  
        $BEGIN
        NAME("ACTLOG"); 
        $END
  
    CONTROL IFEQ OS$NOS;
      IF QRCV                      # IF QTFS #
      THEN
        BEGIN 
        ACLK$LN = XSFW(FILEJBN);   # NAME ON LOCAL HOST # 
        UCLS$LN = ACLK$LN;
        ACLK$RN = XSFW(FILEQFNC);  # NAME ON REMOTE HOST #
        END 
  
      ELSE
        BEGIN 
        ACLK$LN = XSFW(FILEQFNC);  # NAME ON LOCAL HOST # 
        UCLS$LN = ACLK$LN;
        ACLK$RN = XSFW(FILEJBN);   # NAME ON REMOTE HOST #
        END 
  
      ACLK$SC  = FILEORG;          # ASSUME SRV CLASS SAME AS ORIGIN #
      UCLS$SC  = ACLK$SC; 
      ACLK$PID = FILECPDC;         # PID #
      ACLK$LID = FILELIDC;         # LID #
      IF FILECER                   # IF ERROR OCCURRED #
      THEN
        BEGIN 
        ACLK$ERR = ", ERR.";
        END 
  
      ELSE
        BEGIN 
        ACLK$ERR = "."; 
        END 
  
      UCLS$TY   = FILEDCC;         # DISPOSITION CODE # 
      KUN = YCDZ(FILESIZ,9);       # CONVERT FILE SIZE #
      UCLS$KUNU = KUNU;            # UPPER KILOUNITS #
      UCLS$KUNL = KUNL;            # LOWER KILOUNITS #
      MESSAGE(ACLK,AJSNMSGDES);    # ISSUE ACLK MESSAGE # 
      MESSAGE(UCLS,AJSNMSGDES);    # ISSUE UCLS MESSAGE # 
    CONTROL ENDIF;
  
      END  # ACTLOG # 
    TERM
