*DECK,ABORTQ
USETEXT COMCBEG 
USETEXT COMQDEF 
    PROC ABORTQ(NAM); 
      BEGIN    # ABORTQ # 
# 
**    ABORTQ      ABORT QTF/QTFS. 
* 
*     ABORTQ SENDS A DAYFILE MESSAGE CONTAINING THE NAME OF THE 
*     CALLING PROCEDURE AND THEN CALL *ABT*.
* 
*     PROC ABORTQ(NAM)
* 
*     ENTRY      NAM = NAME OF CALLING PROCEDURE
* 
*     EXIT       TO *RPV* VIA *ABT*.
* 
*     PROCESS    SEE ENTRY/EXIT.
# 
  
      ITEM NAM        C(10);       # NAME OF CALLING PROCEDURE #
  
# 
****  XREF
# 
      XREF
        BEGIN 
        PROC ABORT;                # ABORT JOB #
        PROC MSGLOG;               # LOG MESSAGE #
        END 
  
# 
****  XREF END
# 
  
  
      DEF LEMSGABT   #42#;
      ARRAY EMSGABT    S(5);
        BEGIN 
        ITEM $DABT      C(00,00,LEMSGABT) = 
                 [" QTF, ABORT - ERROR IN ROUTINE XXXXXXXXXX."];
        ITEM EMSGABTNAM C(03,06,10);
        END 
  
      EMSGABTNAM = NAM; 
      MSGLOG(LOC(EMSGABT),LEMSGABT);
      ABORT;
  
      END  # ABORTQ # 
    TERM
