*DECK TRANSQ
USETEXT COMCBEG 
USETEXT COMRQUE 
PROC TRANSQ;
# TITLE TRANSQ - TRANSLATE REMOTE CONNECT REQUEST ENTRY TO DISPLAY CD. #
  
      BEGIN  # TRANSQ # 
  
# 
**    TRANSQ - TRANSLATE REMOTE CONNECT REQUEST QUEUE ENTRY.
* 
*     TRANSLATES AND REFORMATS REMOTE CONNECT REQUEST QUEUE ENTRY.
*     FORMAT IS CHANGED FROM "REMOTE CONNECT REQUEST" QUEUE ENTRY TO
*     "CONNECT REQUEST AWAITING ASSIGNMENT" QUEUE ENTRY.  ASCII FIELDS
*     ARE TRANSLATED TO DISPLAY CODE. 
* 
*     PROC TRANSQ.
* 
*     ENTRY   -  QU$ADDRESS IS BASED ARRAY CONTAINING THE REMOTE
*                  CONNECT REQUEST. 
* 
*     EXIT    -  QU$ADDRESS IS BASED ARRAY CONTAINING REFORMATTED ENTRY.
* 
*     PROCESS -  PACK AND CONVERT APPLICABLE FIELDS OF CONNECT REQUEST. 
*                RETURN 
* 
* 
# 
  
# 
****  PROC TRANSQ - XREF LIST BEGIN.
# 
  
      XREF
        BEGIN 
        FUNC ASCTODC C(10);          # CONVERT FROM ASCII TO DISPL CODE#
        END 
  
# 
****  PROC TRANSQ - XREF LIST END.
# 
  
  
      ITEM ANAME1 I;                 # TEMP CELL - ANAME1 IN ASCII #
      ITEM ANAME2 I;                 # TEMP CELL - ANAME2 IN ASSII #
      ITEM PID    I;                 # TEMP CELL - PID IN ASCII # 
      ITEM PASSWRD I;                # TEMP CELL - PASSWRD IN ASCII # 
  
CONTROL EJECT;
  
      ANAME1 = QU$CONAN1A * (2**32) + QU$CONAN1B; 
      ANAME2 = QU$CONAN2A * (2**52) + QU$CONAN2B; 
      PID    = QU$CONPID; 
      QU$REMABN = QU$CONABNA * (2**16) + QU$CONABNB;
      PASSWRD= QU$CONPWA  * (2**12) + QU$CONPWB;
      QU$ANAME1 = ASCTODC (ANAME1,7); 
      QU$ANAME2 = ASCTODC(ANAME2,7);
      QU$REMPID = ASCTODC(PID,3); 
      QU$PASSWD = ASCTODC(PASSWRD,7); 
      QU$LIDREQ = ASCTODC(QU$CONLID,3); 
  
      CONTROL IFEQ OS$NOSBE;
      IF QU$ANAME1  EQ  "PTFS"
      THEN
        BEGIN  # SPECIAL CASE APPLICATION NAME PTFS # 
        QU$ANAME1  =  "FTFS"; 
        END 
      CONTROL ENDIF;
  
      RETURN; 
      END  # TRANSQ # 
  
      TERM
