*DECK SNDSHDM 
USETEXT COMCBEG 
USETEXT COMRAPL 
USETEXT COMRQUE 
USETEXT COMRNAM 
PROC SNDSHDM((SDTYPE)); 
# TITLE SNDSHDM - SEND SHUT DOWN MESSAGE. # 
  
      BEGIN  # SNDSHDM #
  
# 
**    SNDSHDM - SEND SHUT DOWN MESSAGE. 
* 
*     SENDS SHUT DOWN MESSAGE TO ACTIVE UCP"S.
* 
*     ENTRY   - SDTYPE = 0, IF IDLE DOWN. 
*                      = 1, IF NETWORK DISABLED.
* 
*     EXIT    - UCP SHUT/INSD SUPERVISORY MESSAGE QUEUED. 
* 
*     PROCESS - GET QUEUE ENTRY.
*               CONTRUCT ASYNCHRONOUS SUPERVISORY MESSAGE.
*               QUEUE MESSAGE FOR UCP.
# 
  
      ITEM SDTYPE     I;             # SHUT DOWN TYPE # 
  
# 
****  PROC SNDSHDM - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        PROC GETFREE;                # GET FREE QUEUE ENTRY # 
        PROC SUPRPLY;                # INITIATE SUPERVISORY REPLY # 
        END 
  
# 
****  PROC SNDSHDM - XREF LIST END. 
# 
  
  
      ARRAY [0:0] S(1); 
        BEGIN  # SHUT/INSD PRESET # 
        ITEM PRS$WD1    I(00,00,60); # PRESET WORD ONE #
        ITEM PRS$FC     I(00,00,16) = [$SHUINS];
        ITEM PRS$SDTYPE I(00,59,01); # SHUT DOWN TYPE # 
        END 
  
CONTROL EJECT;
  
      GETFREE;
  
      PRS$SDTYPE = SDTYPE;
      QU$SUPWD1 = PRS$WD1;
      $SUPTLC = 1;
      QU$BLKHDR = $SUPHDR;
      QU$CHARGE = 0;
      QU$ERRLGL = FALSE;
  
      SUPRPLY;
  
      END 
  
      TERM
