*DECK RHFUXFR 
USETEXT COMCBEG 
USETEXT COMADEF 
USETEXT COMACBF 
USETEXT COMACBX 
PROC RHFUXFR((ACN),(FETADR),(REQAREA),(FETFC),(CMTYPE));
# TITLE RHFUXFR - USER CONTROLLED FILE TRANSFER. #
  
      BEGIN  # RHFUXFR #
  
# 
**    RHFUXFR - USER CONTROLLED FILE TRANSFER.
* 
*     RHFUXFR IS A SPECIAL ROUTINE DESIGNED TO MAKE RHFXFR
*     REQUESTS TO RHF, BUT ALLOWING THE USER TO CONTROL THE 
*     FLOW OF DATA. 
* 
*     ENTRY   ACN        APPLICATION CONNECTION NUMBER. 
*             FETADR     ADDRESS OF THE USERS FET.
*             REQAREA    ADDRESS OF A THREE WORD BLOCK TO BE
*                        USED AS THE REQUEST BLOCK FOR RHF. 
*             FETFC      FET FUNCTION CODE. 
*             CMTYPE     NAD CONVERSION MODE BEING USED.
* 
*     EXIT    RHF HAS BEEN CALLED WITHOUT RECALL AND CONTROL
*             IS RETURNED TO THE USER.
* 
*     PROCESS CONSTRUCT RHF CALL BLOCK. 
*             CALL RHF. 
*             RETURN. 
# 
  
      ITEM ACN        I;            # APPLICATION CONNECTION NUMBER # 
      ITEM FETADR     I;            # USER FET ADDRESS #
      ITEM REQAREA    I;            # RHF REQUEST AREA #
      ITEM FETFC      I;            # FET FUNCTION CODE # 
      ITEM CMTYPE     I;            # CONVERT MODE TYPE # 
  
# 
****  PROC RHFUXFR - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        PROC CALLSYS;                # MAKES RA + 1 CALLS # 
        END 
  
# 
****  PROC RHFUXFR - XREF LIST END. 
# 
  
  
                                               CONTROL EJECT; 
  
      P<RHFREQREPB> = REQAREA;
  
      RHF$WORD$0[0] = 0;
      RHF$WC = 2; 
      RHF$FNCNUM = NETXFRFUNC;
      RHF$ACN = ACN;
      RHF$ATA = BKF$ATA;
      RHF$FETFC = FETFC;
      RHF$CMTYPE = CMTYPE;
      RHF$RFETAD = FETADR;
  
      SSCXPARAMA[0] = REQAREA;
      CALLSYS(SSCXCALL);
      DBGXFT = DBGXFT + 1;
      DBGUXFR = DBGUXFR + 1;
  
      END  # RHFUXFR #
  
      TERM
