*DECK RHFMSGJ 
USETEXT COMCBEG 
PROC RHFMSGJ(JOBNAME,MESSAGE,LENGTH); 
# TITLE RHFMSGJ - SEND UCP JOBNAME AND MESSAGE TO RHF DAYFILE. #
  
      BEGIN  # RHFMSGJ #
  
# 
**    RHFMSGJ - SEND UCP JOBNAME AND MESSAGE TO RHF DAYFILE.
* 
*     SENDS GIVEN JOB NAME AND SPECIFIED MESSAGE TO RHF AND 
*     SYSTEM DAYFILES.
* 
*     PROC RHFMSGJ(JOBNAME,MESSAGE,LENGTH). 
* 
*     ENTRY   -  JOBNAME IS JOBNAME TO BE PREFIXED TO MESSAGE.
*                MESSAGE IS MESSAGE TO BE SENT TO DAYFILE.
*                LENGTH  IS LENGTH OF MESSAGE IN CHARACTERS.
* 
*     EXIT    -  JOBNAME AND MESSAGE HAVE BEEN SENT TO THE RHF
*                AND SYSTEM DAYFILES. 
* 
*     PROCESS -  PREFIX JOB NAME ON MESSAGE 
*                ISSUE RHFMSG CALL TO WRITE OUT MESSAGE 
*                RETURN 
* 
* 
# 
  
      ITEM JOBNAME C(7);             # JOB NAME OF UCP #
  
      BASED ARRAY MESSAGE [0:0] S(7); 
        BEGIN 
        ITEM MESSAGE$ C(00,00,70);   # MESSAGE TO BE ISSUED # 
        END 
  
      ITEM LENGTH I;                 # LENGTH OF MESSAGE IN CHARACTERS #
  
# 
****  PROC RHFMSGJ - XREF LIST BEGIN
# 
  
      XREF
        BEGIN 
        PROC RHFMSG;                 # SEND MESSAGE TO DAYFILE #
        END 
  
# 
****  PROC RHFMSGJ - XREF LIST END. 
# 
  
  
      ARRAY MSGAREA [0:0] S(8); 
        BEGIN  # AREA FROM WHICH MESSAGE IS SENT #
        ITEM MSGRHF     C(00,00,05) = ["RHF, "];
      CONTROL IFEQ OS$NOSBE;
        ITEM MSGJOBNAME C(00,30,07);
        ITEM MSGSP1     C(01,12,01) = [" "];
        ITEM MSGDATA    C(01,18,65);
      CONTROL ENDIF;
      CONTROL IFEQ OS$NOS;
        ITEM MSGJOBNAME C(00,30,04);
        ITEM MSGSP1     C(00,54,01) = [" "];
        ITEM MSGDATA    C(01,00,65);
      CONTROL ENDIF;
        END 
  
CONTROL EJECT;
  
      MSGJOBNAME = JOBNAME; 
      MSGDATA    = MESSAGE$;
    CONTROL IFEQ OS$NOSBE;
      RHFMSG(LOC(MSGAREA),LENGTH+13); 
    CONTROL ENDIF;
    CONTROL IFEQ OS$NOS;
      RHFMSG(LOC(MSGAREA),LENGTH+10); 
    CONTROL ENDIF;
      RETURN; 
      END  # RHFMSGJ #
  
      TERM
