*DECK REQSTAT 
USETEXT COMCBEG 
USETEXT COMRNET 
USETEXT COMRQUE 
PROC REQSTAT; 
# TITLE REQUSTAT - REQUEST NAD STATUS # 
  
      BEGIN  # REQSTATUS #
  
# 
**    REQSTAT - REQUEST NAD STATUS. 
* 
*     QUEUES A STATUS REQUEST FOR A LOCAL NAD IF ONE IS NOT ALREADY 
*     QUEUED. 
* 
*     PROC REQSTAT: 
* 
*     ENTRY   -  NAD$ENTRY IS LOCAL NAD ENTRY FOR WHICH STATUS REQUEST
*                  IS TO BE QUEUED. 
* 
*     EXIT    -  STATUS REQUEST QUEUED (IF APPROPRIATE) 
* 
*     PROCESS -  IF A STATUS REQUEST IS NOT CURRENTLY QUEUED
*                  AND EITHER THE NAD IS ON 
*                          OR THE NAD CONNECTION COUNT IS NON-ZERO
*                THEN:  
*                  OBTAIN A FREE QUEUE ENTRY
*                  BUILD STATUS REQUEST QUEUE ENTRY 
*                 QUEUE ON NAD QUEUE
*                  SET STATUS QUEUED BIT. 
*                RETURN 
* 
* 
****  PROC REQSTAT - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        PROC GETFREE;                # OBTAIN FREE QUEUE ENTRY #
       PROC QUEUE;
        END 
  
# 
****  PROC REQSTAT - XREF LIST END. 
# 
  
  
CONTROL EJECT;
  
      IF    NOT NAD$STATQ 
        AND (NOT (NAD$ESTOFF OR NAD$PREVOF) 
        OR  NAD$CCOUNT NE 0 ) 
      THEN
        BEGIN  # QUEUE STATUS REQUEST # 
        GETFREE;
        QU$TYPE = QT$STATUS;
        NAD$STATQ = TRUE; 
        QUEUE(LOC(NAD$Q));
        NAD$QCOUNT = NAD$QCOUNT + 1;
        END 
  
      RETURN; 
      END  # REQSTAT #
  
      TERM
  
