*DECK REMDAYF 
USETEXT COMCBEG 
USETEXT COMRNET 
USETEXT COMRQUE 
USETEXT COMRRTN 
PROC REMDAYF(CODE,NADORD);
# TITLE REMDAYF - DAYFILE ACCEPT OF REJECT FOR REMOTE CONNECT REQUEST. #
  
      BEGIN  # REMDAYF #
  
# 
**    REMDAYF - DAYFILE REMOTE CONNECT REQUEST ACCEPT/REJECT. 
* 
*     GENERATES REMOTE CONNECT REQUEST REJECT/ACCEPT MESSAGE AND
*     ISSUES TO RHF CONTROL POINT AND SYSTEM DAYFILES.
* 
*     PROC REMDAYF(CODE,NADORD).
* 
*     ENTRY   -  CODE IS CONNECT REQUEST REPLY CODE (CONR$XXX)
*                QU$ADDRESS IS TRANSLATED REMOTE CONNECT REQUEST
*                  QUEUE ENTRY. 
*                NADORD IS LOCAL NAD TABLE ORDINAL. 
* 
*     EXIT    -  DAYFILE MESSAGE HAS BEEN ISSUED. 
* 
*     PROCESS -  GENERATE DAYFILE MESSAGE 
*                ISSUE DAYFILE MESSAGE
*                RETURN 
* 
* 
# 
  
      ITEM CODE    I;                # CONNECT REQUEST REPLY CODE # 
      ITEM NADORD  I;                # LOCAL NAD ORDINAL #
  
# 
****  PROC REMDAYF - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        FUNC BINTOHD C(10);          # CONVERT TO HEX DISPLAY CODE #
        FUNC BINTOOD C(10);          # CONVERT TO OCTAL DISPLAY CODE #
        ITEM NADTBL  I;              # LOCAL NAD TABLE ADDRESS #
        PROC RHFMSG;                 # ISSUE RHF DAYFILE MESSAGE #
        END 
  
# 
****  PROC REMDAYF - XREF LIST END. 
# 
  
  
      ITEM I I;                      # INDUCTION INDEX #
  
      ARRAY MSGREMCON1 [0:0] S(8);
        BEGIN  # FIRST LINE OF REMOTE CONNECT DAYFILE # 
        ITEM MSGRC      C(00,00,75) =  ["RHF, REMOTE CONNECT REQUEST FRO
M XXXXXXX ON XXX TO XXXXXXX LID=XXX ACCEPTED"]; 
#     OR ---                  . . . REJECTED"]  # 
        ITEM MSGRCAPPL2 C(03,18,07);
        ITEM MSGRCPID   C(04,24,03);
        ITEM MSGRCAPPL1 C(05,06,07);
        ITEM MSGRCLID   C(06,18,03);
        ITEM MSGRCACCPT C(06,42,08);
        END 
  
      ARRAY MSGREMCON2 [0:0] S(7);
        BEGIN  # SECOND LINE OF REMOTE CONNECT DAYFILE #
        ITEM MSGRC2     C(00,00,65) = ["RHF, NAD=XX, CH=XX, BUFF=X, TCU=
XXXX, DEST=X, PATHID=XX, ACC=XXXX"];
        ITEM MSGRC2NAD  C(00,54,02);
        ITEM MSGRC2CH   C(01,36,02);
        ITEM MSGRC2BUFF C(02,30,01);
        ITEM MSGRC2TCU  C(03,12,04);
        ITEM MSGRC2DEST C(04,18,01);
        ITEM MSGRC2PTID C(05,18,02);
        ITEM MSGRC2ACC  C(06,06,04);
        END 
  
      ARRAY MSGDETAIL [1:5] S(5); 
        BEGIN  # DETAILS REASON FOR REMOTE CONNECT REJECT # 
        ITEM MSGDATA    C(00,00,40) = 
                        ["RHF, REQUESTED APPLICATION UNAVAILABLE",
                         "RHF, RHF SHUTDOWN IN PROGRESS", 
                         "RHF, PATH OR NAD UNAVAILABLE",
                         "RHF, PID/LID NOT AVAILABLE",
                         "RHF, INVALID PASSWORD XXXXXXX"];
        ITEM MSGPASSWD  C(02,12,07);
        ITEM MSGCHARCNT I(04,00,60) = [38,29,28,26,28]; 
        END 
  
CONTROL EJECT;
  
      MSGRCAPPL2 = QU$ANAME2; 
      MSGRCAPPL1 = QU$ANAME1; 
      MSGRCPID   = QU$REMPID; 
      MSGRCLID   = QU$LIDREQ; 
      MSGPASSWD[5]  = QU$PASSWD;
      MSGRC2NAD  = BINTOHD(QU$CONNAD,2);
      MSGRC2BUFF = BINTOOD(QU$CONBUFF,1); 
      MSGRC2DEST = BINTOHD(QU$CONDEST,1); 
      MSGRC2PTID = BINTOHD(QU$CONPTID,2); 
      MSGRC2ACC  = BINTOHD(QU$CONACES,4); 
      P<NAD$ENTRY> = NADORD * NAD$LENGTH + NADTBL;
      MSGRC2CH   = BINTOOD(NAD$CHAN,2); 
  
      FOR I = 0 STEP 1 UNTIL 3
      DO
        BEGIN  # GENERATE TCU DISPLAY # 
        C<I,1> MSGRC2TCU  =  B<I,1> QU$CONLT + O"33"; 
        END 
  
      IF CODE NE CONR$OK
      THEN
        BEGIN  # REMOTE CONNECT REJECT #
        MSGRCACCPT = "REJECTED";
        END 
  
      RHFMSG(LOC(MSGREMCON1),75); 
      RHFMSG(LOC(MSGREMCON2),65); 
  
      IF CODE NE CONR$OK
      THEN
        BEGIN  # REMOTE CONNECT REJECT #
        MSGRCACCPT = "ACCEPTED";
        RHFMSG(LOC(MSGDATA[CODE]), MSGCHARCNT[CODE]); 
        END 
  
      RETURN; 
      END  # REMDAYF #
  
      TERM
