*DECK RBLDFET 
USETEXT COMCBEG 
USETEXT COMADEF 
USETEXT COMACBX 
USETEXT COMAFET 
USETEXT COMACBF 
PROC RBLDFET; 
# TITLE  RBLDFET - REBUILD RHF AND LOCAL FETS. #
  
      BEGIN  # RBLDFET #
  
# 
**    RBLDFET - REBUILD RHF AND LOCAL FETS. 
* 
*     THIS ROUTINE IS USED TO CHANGE THE FETS ONCE THE NAD CODE 
*     CONVERSION RESOURCES HAVE BEEN SUCCESSFULLY OBTAINED FOR
*     A GIVEN ACN.
* 
*     PROC RBLDFET. 
* 
*     ENTRY      <FTTENT> = FWA FTT ENTRY.
*                <XFRHOLD> = FWA TRANSFER STATUS TABLE. 
* 
*     EXIT       READY TO BEGIN TRANSFER UTILIZING NAD CODE CONVERSION. 
* 
*     PROCESS    DETERMINE OPTIMUM BUFFER SIZES.
*                RESET BUFFER LIMITS. 
*                CALL BUILDFT TO SET RHF CALL BLOCK AND BUFFER POINTERS.
*                CALL BLDTRT TO BUILD APPROPRIATE TRANSFER STATUS TABLE.
# 
  
# 
****  PROC RBLDFET - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        PROC BLDTRT;                 # BUILD TRANSFER TABLE # 
        PROC BUILDFT;                # BUILD FETS # 
        END 
  
# 
****  PROC RBLDFET - XREF LIST END. 
# 
  
  
      ITEM RFETB      I;             # RHF FET BUFFER SIZE #
      ITEM LFETB      I;             # LOCAL FET BUFFER SIZE #
  
                                               CONTROL EJECT; 
  
      LFETB = XFRMINBUFL[US]; 
      RFETB = XFRMINBUFR[US]; 
      IF FETBUFSIZE GT (LFETB+RFETB)  # IF BUFSIZE GT MINIMUM # 
      THEN
        BEGIN 
        IF FETBUFSIZE GT 2*(LFETB+RFETB)
        THEN
          BEGIN 
          LFETB = 0;
          RFETB = 0;
          END 
  
        LFETB = LFETB + 
              (FETBUFSIZE-LFETB-RFETB)*1000/(XFRRATIO[US]+1000);
        RFETB = FETBUFSIZE - LFETB; 
        END 
  
      P<LFET> = FTTFETADR;       # SET FET POINTERS # 
      P<RFET> = P<LFET> + LEN$LFET + LENRHFPBLK;
      LFETLIM = LFETB;           # SET LOCAL FET BUFFER LENGTH #
      RFETLIM = RFETB;           # SET RHF FET BUFFER LENGTH #
  
      BUILDFT (LFETLFNC);        # BUILD FETS AND RHF PARAM BLOCK # 
  
      BLDTRT(US); 
  
      END  # RBLDFET #
  
      TERM
