*DECK QUITXFR 
USETEXT COMCBEG 
USETEXT COMADEF 
USETEXT COMACBF 
USETEXT COMACBX 
USETEXT COMADFM 
USETEXT COMAFET 
    PROC QUITXFR; 
# TITLE QUITXFR - QUIT DATA TRANSFER. # 
  
      BEGIN  # QUITXFR #
  
# 
**    QUITXFR - QUIT DATA TRANSFER.    .
* 
*     QUITXFR STOPS FURTHER DATA TRANSFER BY ENDING INPUT (IF SENDING) OR 
*                BY SENDING A QUIT COMMAND (IF RECEIVING).
* 
*     ENTRY      <FTTENT> = FWA FTT ENTRY.
*                FTTTSTATIS = ERROR (.GE. SYSTEM$ER). 
* 
*     EXIT       SEE PROCESS. 
* 
*     PROCESS    IF SENDING FILE: 
*                  IF LOCAL FILE BUSY:  
*                    CALL CALLSYS (RECALL) UNTIL COMPLETE.
*                  IF INPUT NOT ENDED:  
*                    SET END OF INFORMATION ON LOCAL FILE.
*                    SET FTTDXPA = P$ES$ERR21.
*                ELSE (RECEIVING FILE): 
*                  SET FTTDXPA = P$ER$ERR21.
*                  IF QUIT NOT SENT:  
*                    CALL PUTLEV7 TO SEND QUIT COMMAND. 
*                    SET FTTQRSENT = TRUE.
# 
  
# 
****  PROC QUITXFR - XREF LIST BEGIN. 
# 
      XREF
        BEGIN 
        PROC CALLSYS;              # SYSTEM CALL RA+1 # 
        PROC PUTLEV7;              # SEND LEVEL 7 MESSAGE # 
        END 
# 
****  PROC QUITXFR - XREF LIST END. 
# 
  
      IF FTTDIRECN EQ SEND         # IF SENDING FILE #
      THEN
        BEGIN 
        IF NOT LFETCOMP            # IF LOCAL FET BUSY #
        THEN
          BEGIN 
          RCLRECALL = TRUE; 
          RCLPARAMAD = P<LFET>; 
          CALLSYS (RCLCALL);
          RCLRECALL = FALSE;
          END 
  
        IF GFETEC NE EOI           # IF INPUT NOT ENDED # 
        THEN
          BEGIN 
          FTTDXPA = P$ES$ERR29; 
          GFETEC = EOI;            # SET END-OF-INFORMATION # 
          END 
  
        END 
  
      ELSE
        BEGIN 
        FTTDXPA = P$ER$ERR21; 
        IF NOT FTTQRSENT           # IF QUIT NOT SENT # 
        THEN
          BEGIN 
          PUTLEV7 (AACMD$QR,FTTDXPA); 
          FTTQRSENT = TRUE; 
          END 
  
        END 
  
      END  # QUITXFR #
  
    TERM
