*DECK PUTNDTM 
USETEXT COMCBEG 
USETEXT COMMCOM 
USETEXT COMMGET 
USETEXT COMRNAM 
USETEXT COMRNET 
USETEXT COMRRTN 
    PROC PUTNDTM (NDTFLAG); 
# TITLE PUTNDTM - SEND SUPERVISORY MESSAGE TO RHF # 
  
      BEGIN  # PUTNDTM #
  
# 
**    PUTNDTM - SEND SUPERVISORY MESSAGE TO RHF.
* 
*     PUTNDTM SENDS RHF A SUPERVISORY MESSAGE CONTAINING
*     AN UPDATED NDT ENTRY WORD.
* 
*     PROC PUTNDTM. 
* 
*     ENTRY      NDTFLAG = 0  NDT WORD
*                        = 1  NST WORD
*                P<BUF1>   = TABLE ADDRESS. 
* 
*     EXIT       SUPERVISORY MESSAGE SENT.
* 
*     PROCESS    SET UP SUPERVISORY MESSAGE 
*                CALL RHFPUT (NETPUT) TO SEND MESSAGE TO RHF
# 
  
      ITEM NDTFLAG    U;           # NDT FLAG # 
  
# 
****  PROC PUTNDTM - XREF LIST BEGIN
# 
      XREF
        BEGIN 
        PROC CALLSYS;              # CALL SYSTEM VIA RA+1 # 
        PROC DBGNAME;              # DEBUG CODE # 
        PROC RHFPUT;               # SEND MESSAGE TO RHF #
        END 
# 
****  PROC PUTNDTM - XREF LIST ENDS 
# 
*CALL HDRAREA 
  
      ARRAY SUPNDT [0:0] S(SUPTXTLGTH); 
        BEGIN 
        ITEM SUPNDT$TY  U(00,00,16);  # MESSAGE TYPE #
        ITEM SUPNDT$EB  B(00,08,01);  # ERROR FLAG #
        ITEM SUPNDT$RB  B(00,09,01);  # RESPONSE FLAG # 
        ITEM SUPNDT$FLG I(00,24,18);  # NDT FLAG #
        ITEM SUPNDT$ORD I(00,42,18);  # ENTRY ORDINAL # 
        ITEM SUPNDT$WD1 U(01,00,60);  # NEW NDT WORD #
        ITEM SUPNDT$WD2 U(02,00,60) = [0];
        END 
  
CONTROL EJECT;
  
      $BEGIN
      DBGNAME ("PUTNDTM");         # DEBUG CODE # 
      $END
  
  
      HDR$WORD = 0; 
      HDR$ABT  = $SUPERABT;        # SUP MESSAGE BLOCK TYPE # 
      HDR$ACT  = SUPCHRTYPE;       # SUP CHARACTER TYPE # 
      HDR$TLCU = SUPTXTLGTH;       # TEXT LENGTH #
  
      SUPNDT$TY  = $STATNDTR;      # STAT/NDT/R # 
      SUPNDT$FLG = NDTFLAG;        # NDT FLAG # 
      SUPNDT$ORD = P<BUF1> - NDTBUF - 1;  # RELATIVE ADDR # 
      SUPNDT$WD1 = BUF1WORD[0];    # UPDATED NDT WORD # 
  
      RHFPUT (HDRAREA,SUPNDT);     # SEND MESSAGE # 
  
      END  # PUTNDTM #
    TERM
