*DECK NPLSTM
USETEXT COMCBEG 
USETEXT COMADEF 
USETEXT COMACBF 
USETEXT COMACBX 
PROC NPLSTM;
# TITLE NPLSTM - NETPUT LIST PROCESSING MESSAGE. #
  
      BEGIN  # NPLSTM # 
  
# 
**    NPLSTM - NETPUT LIST PROCESSING MESSAGE.
* 
*     NPLSTM CALLS CALLNP TO NETPUT EITHER AN LST/ON/R MESSAGE OR AN
*     LST/OFF/R MESSAGE WHICH HAS BEEN SET UP IN ARRAY LST$ON$OFF.
* 
*     PROC NPLSTM 
* 
*     ENTRY      LST MESSAGE IS IN ARRAY LST$ON$OFF.
* 
*     EXIT       LST MESSAGE IS NETPUT. 
* 
*     PROCESS    IF RHF REQUEST NOT COMPLETE: 
*                  CALL CALLSYS (AUTO-RECALL).
*                SET SSC AUTO-RECALL FLAG.
*                CALL CALLNP TO NETPUT THE MESSAGE. 
*                RESTORE THE SSC CALL BACK TO NO RECALL.
# 
  
# 
****  PROC NPLSTM - XREF LIST BEGIN.
# 
  
      XREF
        BEGIN 
        PROC CALLNP;                 # CALL NETPUT #
        PROC CALLSYS;              # CALL SYSTEM #
        END 
  
# 
****  PROC NPLSTM - XREF LIST END.
# 
  
                                               CONTROL EJECT; 
      IF NOT RRB$DONE[0]           # IF RHF REQUEST INCOMPLETE #
      THEN
        BEGIN 
        RCLPARAMAD[0] = LOC(RRBDFT);
        RCLRECALL[0] = TRUE;       # AUTO-RECALL #
        CALLSYS (RCLCALL);
        END 
  
      SSCXRECALL[0]  =  TRUE; 
      CALLNP (HWOASMSG, LST$ON$OFF); # NETPUT THE LST MESSAGE # 
      SSCXRECALL[0] = FALSE;
      END  # NPLSTM # 
  
      TERM
