*DECK NADLOAD 
USETEXT COMCBEG 
USETEXT COMMCOM 
USETEXT COMMGET 
USETEXT COMRNET 
    PROC NADLOAD; 
      BEGIN  # NADLOAD #
#  TITLE  NADLOAD - LOAD NAD CONTROLWARE #
  
# 
**    NADLOAD - LOAD NAD CONTROLWARE
* 
*     ENTRY      DLSTATE = 01 (LOAD-IN-PROGRESS)
*                <NST$ENTRY> = LOCAL/REMOTE NAD ENTRY IN NDT
* 
*     EXIT     - DLSTATE = 00 (NAD READY FOR USE) 
*                        = 01 (LOAD IN-PROGRESS)
* 
*     PROCESS  - SET I.P. NAME, C/W TYPE
*                CALL CMM TO OBTAIN MEMORY FOR C/W AND I.P. 
*                CALL FINDCW TO OBTAIN C/W AND I.P. 
*                CALL LOADCW TO LOAD C/W
*                CALL CMM TO RELEASE MEMORY FOR C/W AND I.P.
# 
  
# 
****  PROC NADLOAD - XREF BEGINS. 
# 
      XREF
        BEGIN 
        PROC DBGNAME;              # DEBUG - DAYFILE MESSAGE #
        PROC FINDCW;               # FIND C/W AND I.P. #
        PROC LOADCW;               # LOAD C/W # 
        FUNC MEMCMM     U;         # GET/RELEASE CMM BUFFER # 
        END 
# 
****  PROC NADLOAD - XREF ENDS. 
# 
  
  
  
  
CONTROL EJECT;
  
      $BEGIN
      DBGNAME ("NADLOAD");         # DEBUG MESSAGE #
      $END
  
      IPNAM = NST$CWIPN;           # I.P. RECORD NAME # 
      CWTYP = NST$CWTYP;           # C/W TYPE # 
  
      IPLEN = ONEPRU*2 + 1;        # LENGTH OF I.P. BUFFER #
      IPBUF = MEMCMM (IPBUF,IPLEN);  # GET I.P. BUFFER #
      IPADR = IPBUF;               # FWA OF I.P. BUFFER # 
  
      CWLEN = CWSIZE + ONEPRU;     # LENGTH OF C/W BUFFER # 
      CWBUF = MEMCMM (CWBUF,CWLEN);  # GET C/W BUFFER # 
      CWADR = CWBUF;               # FWA OF C/W BUFFER #
      CWLEN = CWSIZE;              # LEAVE ROOM FOR I.P. #
      CWNAMU = 0;                  # CLEAR C/W NAME # 
  
      FINDCW;                      # FIND C/W AND I.P. #
  
      IF NOT ERROR                 # IF NO ERROR #
      THEN
        BEGIN 
        LOADCW;                    # LOAD CONTROLWARE # 
        END 
  
      CWLEN = 0;
      IPLEN = 0;
      IPBUF = MEMCMM (IPBUF,IPLEN);  # RELEASE BUFFER # 
      CWBUF = MEMCMM (CWBUF,CWLEN);  # RELEASE BUFFER # 
      ERROR = FALSE;
  
      END  # NADLOAD #
  
    TERM
