*DECK FCNAK 
USETEXT COMCBEG 
USETEXT COMRNAM 
USETEXT COMRNDR 
USETEXT COMRQUE 
PROC FCNAK; 
# TITLE FCNAK - CREATE FC/NAK. #
  
      BEGIN # FCNAK # 
  
# 
**    FCNAK   - CREATE FC/NAK.
* 
*     PROC FCNAK. 
* 
*     ENTRY   - NDR$COMMUN IS BASED ARRAY CONTAINING WRITE COMPLETION.
*               APL$HEADER IS BASED ARRAY CONTAINING APPLICATION TABLE. 
* 
*     EXIT    - FC/NAK IS QUEUED FOR APPLICATION. 
* 
*     PROCESS - OBTAIN FREE QUEUE ENTRY.
*               INITIALIZE ABT, ACT, AND TLC. 
*               INITIALIZE FC/NAK.
*               INSERT ACN AND ABN. 
*               INITIALIZE SUPERVISORY REPLY. 
*               RETURN. 
# 
  
# 
****  PROC FCNAK - XREF LIST BEGIN. 
# 
      XREF
        BEGIN 
        PROC GETFREE;                # OBTAIN FREE QUEUE ENTRY #
        PROC SUPRPLY;                # INITIATE SUPERVISORY REPLY # 
        END 
  
# 
****  PROC FCNAK - XREF LIST END. 
# 
  
  
      ARRAY [0:0] S(1); 
        BEGIN  # FC/NAK PRESET #
        ITEM PRS$WD1    I(00,00,60); # WORD ONE # 
        ITEM PRS$FCNAK  I(00,00,16) = [$FCNAK]; # FC/NAK #
        ITEM PRS$RC     I(00,16,08) = [2]; # RETURN NETWORK BUSY CODE # 
        ITEM PRS$ACN    I(00,24,12); # ACN #
        ITEM PRS$ABN    I(00,36,18); # ABN #
        END 
CONTROL EJECT;
  
      GETFREE;
      $SUPTLC = 1;
      QU$BLKHDR = $SUPHDR;
      PRS$ACN = NDR$ACN;
      PRS$ABN = NDR$ABN;
      QU$SUPWD1 = PRS$WD1;
      QU$CHARGE = 0;
      QU$ERRLGL = FALSE;
      SUPRPLY;
      RETURN; 
      END  # FCNAK #
  
      TERM
