*DECK EXITCM
USETEXT COMCBEG 
USETEXT COMADEF 
USETEXT COMACBX 
PROC EXITCM;
# TITLE  EXITCM - EXIT CONVERT MODE. #
  
      BEGIN  # EXITCM # 
  
# 
**    EXITCM - EXIT CONVERT MODE. 
* 
*     THIS ROUTINE ISSUES A CM/EXIT/R TO RHF TO INITIATE THE
*     EXITING OF A CONVERT MODE.
* 
*     PROC EXITCM.
* 
*     ENTRY      <FTTENT> = FWA FTT ENTRY (WITH CORRESPONDING ACN). 
* 
*     EXIT       CM/EXIT/R ISSUED AND STATE UPDATED.
* 
*     PROCESS    IF CM/EXIT/R ALREADY ISSUED
*                THEN 
*                  CALL XFRCOMP TO COMPLETE THE FILE TRANSFER.
*                ELSE 
*                  ISSUE CM/EXIT/R. 
*                  SET TIMEOUT. 
*                  SET EXITING CONVERT MODE FLAG. 
*                  SET STATE TO WAITING FOR CONVERT MODE EXIT RESPONSE. 
# 
  
# 
****  PROC EXITCM - XREF LIST BEGIN.
# 
  
      XREF
        BEGIN 
        PROC CALLNP;                 # ISSUE NETPUT REQUEST # 
        PROC INITIME;                # INIALIZE TIMEOUT TIMER # 
        PROC XFRCOMP;                # COMPLETE FILE TRANSFER # 
        END 
  
  
                                               CONTROL EJECT; 
  
      IF FTTCMEA
      THEN
        BEGIN 
        XFRCOMP;
        END 
  
      ELSE
        BEGIN 
        CSE$PFC = CM$EXIT$R;
        CSE$ACN = FTTACN; 
        SSCXRECALL = TRUE;
        CALLNP(HWOASMSG,CM$SEL$EXT);
        SSCXRECALL = FALSE; 
        INITIME;
        FTTCMEA = TRUE; 
        FTTSTATE =  S"WFORECMR";
        END 
  
      END  # EXITCM # 
  
      TERM
