*DECK ENDXFR
USETEXT COMCBEG 
USETEXT COMADEF 
USETEXT COMACBF 
USETEXT COMACBX 
USETEXT COMAFET 
USETEXT COMADFM 
USETEXT COMAMCB 
PROC ENDXFR;
# TITLE ENDXFR - COMPLETE ACTUAL DATA TRANSFER.  #
  
      BEGIN  # ENDXFR # 
  
# 
**    ENDXFR - COMPLETE ACTUAL DATA TRANSFER. 
* 
*     ENDXFR PROCESS EOR/EOF/EOI WRITES FOR BOTH SENDING AND RCEIVING 
*     A FILE. 
* 
*     PROC ENDXFR 
* 
*     ENTRY      LOCAL AND RHF FETS ARE COMPLETE. 
*                <FTTENT> = FWA FTT ENTRY.
*                FTTDXPA = TRANSFER STATUS (OK OR ERROR). 
* 
*     PROCESS    IF FILE TRANSFER ERROR WAS ENCOUNTERED 
*                THEN 
*                  CALL XFRCOMP TO TERMINATE THE TRANSFER.
*                ELSE 
*                  IF SEND
*                  THEN 
*                    SEND ES TO REMOTE. 
*                    SET STATE TO WAITING FOR ES ACK. 
*                  ELSE 
*                    SET STATE TO WAITING FOR ES. 
*                CALL INITIME TO RESET TIMER. 
# 
  
# 
****  PROC ENDXFR - XREF LIST BEGIN.
# 
  
      XREF
        BEGIN 
        PROC INITIME;                # INITIALIZE FITTIME # 
        PROC PUTLEV7;                # SEND LEVEL 7 COMMAND # 
        PROC XFRCOMP;                # TERMINATE THE FILE TRANSFER #
        END 
  
# 
****  PROC ENDXFR - XREF LIST END.
# 
  
  
  
  
  
                                               CONTROL EJECT; 
      IF FTTERRORD NE 0 
      THEN
        BEGIN 
        XFRCOMP;
        END 
  
      ELSE
        BEGIN 
        IF FTTDIRECN EQ SEND
        THEN
          BEGIN 
          PUTLEV7(AACMD$ES,FTTDXPA);
          FTTSTATE = S"ESISSWFACK"; 
          END 
  
        ELSE
          BEGIN 
          FTTSTATE = S"EOIRCVWFES"; 
          END 
  
        END 
  
      INITIME;                     # RESET TIMER #
      END    # ENDXFR # 
  
      TERM
