*DECK DLYRTRY 
USETEXT COMCBEG 
USETEXT COMRAPL 
PROC DLYRTRY; 
# TITLE DLYRTRY - RETRY REQUESTS ON DELAY Q # 
  
      BEGIN  # DLYRTRY #
  
# 
**    DLYRTRY - RETRY REQUESTS ON DELAY QUEUE.
* 
*     GIVES REQUESTS ON THE DELAY QUEUE BACK TO NDR TO RETRY. 
* 
*     PROC DLYRTRY. 
* 
*     ENTRY   -  APL$HEADER IS BASED ARRAY CONTAINING APPLICATION HDR.
* 
*     EXIT    -  DELAY QUEUE REQUESTS QUEUED FOR NDR TO RETRY.
* 
*     PROCESS -  FOR EACH CONNECTION TABLE ENTRY: 
*                  IF THE PATH IS DEFINED AND FC/INIT/N RECEIVED
*                  THEN:  
*                    FOR EACH ENTRY ON THE DELAY QUEUE: 
*                      DEQUEUE ENTRY
*                      INITIATE TRANSMITTAL OF REQUEST TO NDR TO RETRY. 
*                RETURN 
* 
* 
****  PROC DLYRTRY - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        PROC DEQUEUE;                # REMOVE ENTRY FROM QUEUE #
        PROC NADREQ;                 # QUEUE REQUEST FOR NDR PROCESSING#
        END 
  
# 
****  PROC DLYRTRY - XREF LIST END. 
# 
  
  
      ITEM INDX I;                   # INDEX FOR CONNECT TABLE SEARCH # 
  
CONTROL EJECT;
  
      P<CONNECTION> = P<APL$HEADER> + APL$LENGTH; 
  
      SLOWFOR INDX = 0 STEP 1 UNTIL (APL$MAXACN - APL$MINACN) 
      DO
        BEGIN  # SEARCH THROUGH CONNECTION ENTRIES #
  
        IF    CON$PATHID NE 0 
          AND CON$INIT$N
        THEN
          BEGIN  # CHECK FOR ENTRIES ON DELAY QUEUE # 
  
          ASLONGAS CON$DELAYQ NE 0
          DO
            BEGIN  # GIVE DELAY Q ENTRY TO NDR TO RE-TRY #
            DEQUEUE(LOC(CON$DELAYQ)); 
            NADREQ(CON$NADORD); 
            END 
  
          END 
  
        P<CONNECTION> = P<CONNECTION> + CON$LENGTH; 
        END 
  
      RETURN; 
      END  # DLYRTRY #
  
      TERM
  
