*DECK,DBGSMSG 
          IDENT  DBGSMSG
          TITLE  DBGSMSG - DISPLAY FIP DEBUG STATISTICS MESSAGE.
          ENTRY  DBGSMSG
          SYSCOM B1 
          SPACE  4,10 
***       DBGSMSG - DISPLAY FIP DEBUG STATISTICS MESSAGE. 
* 
*         CALL DBGSMSG (TEXT, VALUE)
* 
*         WHERE  TEXT = UP TO 7 CHARACTERS BLANK-FILLED,
*                VALUE = INTEGER VALUE TO BE OUTPUT.
* 
*         EXIT   FORMATTED MESSAGE SENT TO DAYFILE
* 
*         FIP - NNNN CALLS TO XXXXXX
          SPACE  4,10 
 DBGSMSG  SUBR
          SB1    1
          SA2    A1+B1       ADDRESS OF SECOND PARAMETER
          SA3    X1          FETCH TEXT 
          MX0    7*6
          BX6    X0*X3       MASK UPPER SEVEN CHARACTERS
          SA6    DBGC        STORE IN MESSAGE 
          SA1    X2          FETCH VALUE
          RJ     =XCDD=      CONVERT TO DECIMAL DPC 
          SA1    DBGA 
          MX0    4*6
          BX6    -X0*X6      MASK LOW SIX CHARS 
          BX1    X0*X1       MASK UPPER FOUR CHARS
          BX6    X1+X6
          SA6    A1 
  
          MESSAGE A1,,RCL 
  
          EQ     DBGSMSG     RETURN 
  
 DBGA     BSS    0
          CON    10H FIP NNNNN
          CON    10H CALLS TO 
 DBGC     CON    0
  
          END 
