*DECK DBGNAME 
    PROC DBGNAME(NAM);
# TITLE   DBGNAME - DEBUG NAME (DAYFILE MESSAGE) #
  
# 
**    DBGNAME - DEBUG NAME (DAYFILE MESSAGE)
* 
*     THIS PROCEDURE SENDS A DAYFILE MESSAGE OF THE FORM
*       * MHF DEBUG-XXXXXXXXXX ENTERED *
* 
*     ENTRY     NAM = 10-CHARACTER STRING.
* 
*     EXIT      MESSAGE SENT TO DAYFILE.
# 
      BEGIN  # DBGNAME #
  
      ITEM NAM C(10);              # INPUT PARAMETER #
  
      $BEGIN                       # DEBUG CODE # 
  
      XREF
        BEGIN 
        PROC CALLSYS;              # CALL SYSTEM VIA RA+1 # 
        END 
      DEF MSG$DAYF   # 0 #;        # DAYFILE MESSAGE DESTINATION #
  
      ARRAY MSGCALL S(2); 
        BEGIN 
        ITEM MSG$WORD0  U(00,00,60) = [0];
        ITEM MSG$NAME   C(00,00,04) = ["MSGP"]; 
        ITEM MSG$DSPLAY U(00,24,12);
        ITEM MSG$STATWD I(00,42,18);
        ITEM MSG$STATUS I(01,30,30);
        ITEM MSG$BUFADR I(01,00,30);
        END 
  
      ARRAY NAMSG S(3); 
        BEGIN 
        ITEM NAMSG0     C(00,00,10) = ["MHF DEBUG-"]; 
        ITEM NAMSG1     C(01,00,10);
        ITEM NAMSG2     C(02,00,08) = [" ENTERED"]; 
        ITEM NAMSGT     U(02,48,12) = [0];
        END 
  
  
      NAMSG1[0] = NAM;             # PUT NAME IN DEBUG MESSAGE #
      MSG$BUFADR = LOC(NAMSG0); 
      MSG$STATWD = LOC(MSG$STATUS); 
      MSG$STATUS = 0; 
      MSG$DSPLAY = 3; 
      CALLSYS (MSGCALL);           # DAYFILE MESSAGE #
      MSG$DSPLAY = MSG$DAYF;       # RESET MESSAGE DESTINATION #
  
      $END                         # END DEBUG CODE # 
      END  # NAME # 
    TERM
