*DECK CONREQA 
USETEXT COMCBEG 
USETEXT COMRAPL 
USETEXT COMRQUE 
USETEXT COMRRTN 
PROC CONREQA; 
# TITLE CONREQA - PROCESS SUPERVISORY MESSAGE CON/REQ/A. #
  
      BEGIN  # CONREQA #
  
# 
**    CONREQA - PROCESS CON/REQ/A SUPERVISORY MESSAGE.
* 
*     PROCESS REJECT CONNECT ASYNCHRONOUS SUPERVISORY MESSAGE 
*     (CON/REQ/A).
* 
*     PROC CONREQA. 
* 
*     ENTRY   - APL$HEADER IS BASED ARRAY FOR APPLICATION TABLE HEADER. 
*               QU$ADDRESS IS BASED ARRAY FOR CON/REQ/A SUPR MSG. 
*               CONNECTION IS BASED ARRAY FOR ACN.
* 
*     EXIT    - CON/REQ/A/ SUPERVISORY MESSAGE IS PROCESSED.
* 
*     PROCESS - IF CON/REQ/R NOT SENT 
*               THEN: 
*                 PUT REQUEST ON ERR/LGL QUEUE. 
*                 FREE QUEUE ENTRY. 
*               ELSE: 
*                 RELEASE CONNECTION TABLE ARRAY. 
*                 REMOVE AND FREE CONNECTION REQUEST ENTRY FROM DELAY Q.
*                 UPDATE NSUP.
*               RETURN
* 
* 
****  PROC CONREQA - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        PROC DEQUEUE;              # REMOVE ENTRY FROM QUEUE #
        PROC FREE;                 # RELEASE QUEUE ENTRY #
        PROC FREEACN;              # RELEASE CONNECTION ENTRY # 
        PROC QUEUE;                # ADD ENTRY TO QUEUE # 
        PROC QERRLGL;              # QUEUE ON ERR/LGL QUEUE # 
        PROC RTNNSUP;              # INITIATE NSUP UPDATE # 
        END 
  
# 
****  PROC CONREQA - XREF LIST END. 
# 
  
  
      ITEM QUEADR I;               # TEMP CELL - CON/REQ/A ENTRY #
  
CONTROL EJECT;
  
      IF NOT CON$REQ$R
        OR CON$REQ$N
        OR CON$PATHID EQ 0
      THEN
        BEGIN  # PROTOCOL ERROR # 
        QERRLGL(LGL$PROTCL,0,QU$UCPA,QU$BLKHDR,QU$SUPWD1,0,0);
        FREE; 
        END 
  
      ELSE
        BEGIN  # CON/REQ/A ACCEPTABLE # 
        QUEADR = P<QU$ADDRESS>; 
        DEQUEUE(LOC(CON$DELAYQ)); 
        FREE; 
        FREEACN(QT$DISCON); 
        P<QU$ADDRESS> = QUEADR; 
        RTNNSUP;
        END 
  
      RETURN; 
      END  # CONREQA #
  
      TERM
