*DECK CLRPTHR 
USETEXT COMCBEG 
USETEXT COMRNET 
PROC CLRPTHR; 
# TITLE CLRPTHR - CLEAR PATH REJECT BITS. # 
  
      BEGIN  # CLRPTHR #
  
# 
**    CLRPTHR - CLEAR PATH REJECT BITS. 
* 
*     CLEARS "LAST CONNECT REQUEST REJECTED" BIT IN ALL PATH ENTRIES. 
* 
*     PROC CLRPTHR. 
* 
*     ENTRY   -  NONE 
* 
*     EXIT    -  ALL PATH REJECT BITS CLEARED.
* 
*     PROCESS -  FOR EACH PID HEADER: 
*                  FOR EACH PATH ENTRY: 
*                    CLEAR PATH REJECT BIT..
*                RETURN 
* 
* 
# 
  
# 
*     PROC CLRPTHR - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        ITEM NDTADDR  I;             # NETWORK DEFINITION TABLE ADDR #
        END 
  
# 
*     PROC CLRPTHR - XREF LIST END. 
# 
  
  
      ITEM PTHINDX I;                # INDUCTION VARIABLE FOR PATH LOOP#
  
CONTROL EJECT;
  
      P<NET$HEADER> = NDTADDR;
  
      ASLONGAS P<NET$HEADER> NE 0 
      DO
        BEGIN  # LOOK AT NEXT PID # 
        P<PTH$ENTRY>  = NET$PATHAD; 
  
        SLOWFOR PTHINDX = 1 STEP 1 UNTIL NET$NMPATH 
        DO
          BEGIN  # LOOK THRU PATH TABLE ENTRIES # 
          IF PTH$REJ
          THEN
            BEGIN  # CLEAR PATH REJECT BIT #
            PTH$REJ = FALSE;
            END 
  
          P<PTH$ENTRY> = P<PTH$ENTRY> + PTH$LENGTH; 
          END 
  
        P<NET$HEADER> = NET$NXTPID; 
        END 
  
      RETURN; 
      END  # CLRPTHR #
  
      TERM
  
