*DECK CKOPMSG 
USETEXT COMCBEG 
USETEXT COMRLRA 
USETEXT COMRQUE 
PROC CKOPMSG; 
# TITLE CKOPMSG - CHECK FLASHING OPERATOR MESSAGE. #
  
      BEGIN  # CKOPMSG #
  
# 
**    CKOPMSG - CHECK FLASHING OPERATOR MESSAGE.
* 
*     CKOPMSG CHECKS IF THE FLASHING OPERATOR MESSAGE HAS BEEN
*     ACKNOWLEDGED. 
* 
*     PROC CKOPMSG. 
* 
*     ENTRY   - NONE. 
* 
*     EXIT    - MESSAGE CLEARED AND BLANK DAYFILE MESSAGE ISSUED IF 
*               OPERATOR ACKNOWLEDGED FLASHING MESSAGE. 
* 
*     PROCESS - IF ENTRY ON FLSHMSGQ
*                 AND ACK BIT SET (NOS/BE) OR PAUSE BIT CLEAR (NOS) 
*               THEN
*                 CLEAR ACK BIT (NOS/BE)
*                 FREE TOP MESSAGE ON QUEUE.
*                 CALL RHFMSG TO CLEAR B-DISPLAY. 
* 
* 
****  PROC CKOPMSG - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        PROC DEQUEUE;                # REMOVE ENTRY FROM QUEUE #
        PROC FREE;                   # FREE QUEUE ENTRY # 
        PROC RHFMSG;               # SEND DAYFILE TO RHF CTL PT. #
        END 
  
# 
****  PROC CKOPMSG - XREF LIST END. 
# 
  
  
      ITEM BLANKMSG   C(1) = " "; 
  
CONTROL EJECT;
CONTROL IFEQ OS$NOS;
      IF FLSHMSGQ NE 0
        AND NOT RA$PAUSE           # OPERATOR ENTERED *GO* #
      THEN
        BEGIN 
CONTROL ENDIF;
CONTROL IFEQ OS$NOSBE;
      IF FLSHMSGQ NE 0
        AND RA$ACK
      THEN
        BEGIN 
        RA$ACK = FALSE; 
CONTROL ENDIF;
        DEQUEUE(LOC(FLSHMSGQ)); 
        FREE; 
        RHFMSG(LOC(BLANKMSG),1);   # CLEAR B-DISPLAY #
        END 
  
      END  # CKOPMSG #
  
      TERM
