*DECK CALLNP
USETEXT COMCBEG 
USETEXT COMADEF 
USETEXT COMACBF 
USETEXT COMACBX 
PROC CALLNP(HDRAREA,TEXTAREA);
# TITLE CALLNP - CALL NETPUT.  #
  
      BEGIN  # CALLNP # 
  
# 
*     CALLNP - CALL NETPUT. 
* 
*     CALLNP MAKES A CALL TO THE RHF SUBSYSTEM IN ORDER TO PERFORM
*     A NETPUT FUNCTION OF AN ASYNCHRONOUS SUPERVISORY MESSAGE OR FOR 
*     A LEVEL 7 COMMAND.
* 
*     PROC CALLNP(HDRAREA,TEXTAREA) 
* 
*     ENTRY      HDRAREA - HEADER WORD ADDRESS. 
*                TEXTAREA   - TEXT AREA ADDRESS.
*                SSCXRECALL - SET TO TRUE IF RECALL IS DESIRED. 
*                RRB$DONE = TRUE (LAST RHF REQUEST COMPLETE). 
* 
*     EXIT       NONE.
* 
*     PROCESS    PLACE HDRAREA, TEXTAREA, AND THE NETPUT FUNCTION 
*                  INTO THE RHF REQUEST BLOCK.
*                CALL SYSTEM TO MAKE AN RA+1  CALL FOR SSC
*                  SO THAT RHF CAN PERFORM A NETPUT FUNCTION. 
* 
# 
  
*CALL HDRAREA 
*CALL TEXTAREA
  
# 
****  PROC CALLNP - XREF LIST BEGIN.
# 
  
      XREF
        BEGIN 
        PROC DBGMSG;                 # WRITE DEBUG DAYFILE MESSAGE #
        PROC CALLSYS;                # MAKES RA+1 CALLS # 
        END 
  
# 
****  PROC CALLNP - XREF LIST END.
# 
                                               CONTROL WEAK DBGMSG; 
                                               CONTROL EJECT; 
  
      IF DBUGSUP OR DBUGDAT 
      THEN
        BEGIN 
        DBGMSG (LOC (HDRAREA), LOC (TEXTAREA), TRUE); 
        END 
  
      RRB$ACN[0] = HDR$ACN[0];
      RRB$HDRADR[0]  =  LOC (HDRAREA);
      RRB$TEXTAD[0]  =  LOC (TEXTAREA); 
      RRB$FNCNUM[0]  =  NETPUTFUNC; 
      RRB$DONE[0] = FALSE;
      SSCXPARAMA[0] = LOC (RRBDFT); 
      CALLSYS (SSCXCALL);            # ISSUE TO RHF SUBSYSTEM # 
      DBGXNP = DBGXNP + 1;
  
      END    # CALLNP # 
  
      TERM
